为什么我的程序使用 Perl 的 getc 函数无法正常工作？

Question

我想使用 Perl 计算消息中字符出现的频率。例如，如果字符“a”在消息中出现 10 次，则频率将为 10。为此，我使用 getc 函数。这是我写的片段。我知道这是非常基本的。但是，当我编译时，出现错误：

详细信息：

#!/usr/bin/perl

use strict;
use warnings;

my $input=$ARGV[0];

open(INPUT,"<$input");

while(<INPUT>
{
 my $c=getc(INPUT);
 print $c."\n";
}

close(INPUT);

当我尝试编译它时，出现以下错误：

Use of uninitialized value in print at AccessChar.pl line 13, ;第 1 行。

我无法弄清楚这个脚本有什么问题。有人可以帮我解决这个问题吗？

我什至尝试使用 getc INPUT 而不是 getc(INPUT)。我认为运行此脚本时不需要包含任何其他包。

Answer 1

while (<INPUT>)

将在循环的每次迭代中从 INPUT 读取整行。如果您想一次处理一个字符该文件句柄，那么它不是正确的结构。

尝试类似的方法：

my $c;
while (defined($c = getc(INPUT))) {
  print $c, "\n";
}

Answer 2

将文件读取运算符 (< ... >) 与 getc 混合使用是一个坏主意。它没有按照你的想法去做。

尝试将一些调试输出放入程序中以查看发生了什么。我通过运行程序本身来测试该程序（./getc getc）。

在 while 循环开始时， 从文件中读取一行并将其存储在 $_ 中。然后，您可以使用 getc 从文件中读取下一个字符。这将是文件第二行的第一个字符（可能是换行符 - 它可能是该行上的唯一字符）。

下一次循环时， 读取下一行输入。这就是 use strict 行。 getc 读取下一个字符，即来自 use warnings 的“u”。

如此一直持续到文件末尾。 读取一行，然后 getc 读取下一行的第一个字符。

那根本不是你想要的。如果您想一次读取一个字符，那么您只需要getc。

#!/usr/bin/perl

use strict;
use warnings;

my $input = shift;

open(my $file, '<', $input);

while (defined(my $c = getc $file)) {
  print "$c\n";
}

另一种选择是只使用 < ... > 并在阅读时分割每一行。

#!/usr/bin/perl

use strict;
use warnings;

my $input = shift;

open(my $file, '<', $input);

while (<$file>) {
  foreach my $c (split //) {
    print "$c\n";
  }
}

但混合这两种方法是行不通的。

Answer 3

只是为了一点 TIMTOWTDI：

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;

local $/;
my %chars;

$chars{$_}++ for split //, <>;

print Dumper \%chars;

只要文件不是太大而无法吞咽，它就可以工作；如果是读取并分割每一行。用法：

$ count_chars.pl file_to_read