打印 Mnesia 表的最佳方式

Question

我尝试了这个代码片段：

print_next(Current) ->
    case mnesia:dirty_next(muppet, Current) of
        '$end_of_table' ->
            io:format("~n", []),
            ok;
        Next ->
            [Muppet] = mnesia:dirty_read({muppet, Next}),
            io:format("~p~n", [Muppet]),
            print_next(Next),
            ok
    end.

print() ->
    case mnesia:dirty_first(muppet) of
        '$end_of_table' ->
            ok;
        First ->
            [Muppet] = mnesia:dirty_read({muppet, First}),
            io:format("~p~n", [Muppet]),
            print_next(First),
            ok
    end.

但它太长了。我也可以使用 dirty_all_keys 然后遍历键列表，但我想知道是否有更好的方法来打印 Mnesia 表内容。

Answer 1

如果您只是想要一种快速而肮脏的方式在 shell 中打印 Mnesia 表的内容，并且您的表不是 disc_only_copies 类型，那么您可以利用 Mnesia 存储其表的事实ETS 表中的数据并运行：

ets:tab2list(my_table).

或者，如果您认为 shell 截断数据太多：

rp(ets:tab2list(my_table)).

当然，不建议用于“真实”代码。

Answer 2

要简单快速地查看表格内容，您可以使用 mnesia 的 select 功能和 catch-all 匹配规范如下：

CatchAll = [{'_',[],['$_']}].
mnesia:dirty_select(TableName, CatchAll).

您也可以在事务上下文中运行它：

CatchAll = [{'_',[],['$_']}].
SelectFun = fun() -> mnesia:select(TableName, CatchAll) end.
mnesia:transaction(SelectFun).

但是，如果您处于具有大数据的生产环境中，请小心。

Answer 3

好吧，如果目的是查看表的内容，则有一个名为 tv，可以查看 ETS 和 mnesia 表。

如果您希望在终端上查看所有表格内容，请尝试如下操作：

traverse_table_and_show(Table_name)->
    Iterator =  fun(Rec,_)->
                    io:format("~p~n",[Rec]),
                    []
                end,
    case mnesia:is_transaction() of
        true -> mnesia:foldl(Iterator,[],Table_name);
        false -> 
            Exec = fun({Fun,Tab}) -> mnesia:foldl(Fun, [],Tab) end,
            mnesia:activity(transaction,Exec,[{Iterator,Table_name}],mnesia_frag)
    end.

然后，如果您的表格名为 muppet，则可以按如下方式使用该函数：

traverse_table_and_show(muppet).

这样做的优点：
如果在事务内执行，就不会有嵌套事务的问题。与 get_next_key -> 的实现相比，它的工作量更少，因为它通过 mnesia 迭代器功能在一个 mnesia 事务中完成。 do_read_with_key ->;然后读取记录（这些操作很多）。这样，mnesia 就会自动告诉你它已经覆盖了你整个表中的所有记录。此外，如果表是分段的，您的功能将仅显示第一个分段中的记录。这将迭代属于该表的所有片段。

在此迭代 mnesia 方法中，我对 Accumulator 变量不执行任何操作，该变量应与 Iterator 函数一起使用，这就是为什么您会看到第二个变量的下划线。

此迭代的详细信息可以在这里找到：< /a>http://www.erlang.org/doc/man/mnesia.html#foldl-3

Answer 4

正如 Muzaaya 所说，您可以使用 tv（表可视化工具）来查看 mnesia 和 ets 表。
或者，您可以使用以下代码获取 mnesia 表数据 - 在终端上打印或者如果您想将结果存储在文件中：

select_all() -> 
   mnesia:transaction( 
fun() ->
    P=qlc:e(qlc:q([E || E <- mnesia:table(tableName)])),      %query to select all data from table named 'tableName'                                                                                    
    io:format(" ~p ~n ", [P]), % Prints table data on terminal
    to_file("fileName.txt",P) % to_file method writes the data to file
end ).


to_file(File, L) ->
  mnesia:transaction( 
fun() ->
      {ok, S} = file:open(File, write),
      lists:foreach(fun(X) -> io:format(S, "~p.~n" ,[X]) end, L),
      file:close(S)
  end).