匹配 Razor 之类表达式的正则表达式

Question

我一直在试图找出如何匹配类似 Razor 的嵌入表达式。这不是真正的 Razor 语法，只是类似的语法。

示例：

给定以下字符串：

这个@ShouldMatch1和这个@ShouldMatch2还有这个 @((ShouldNotMatch1)andthis@ShouldMatch3) 和这个@(ShouldNotMatch2 这个@1ShouldNotMatch3 和这个@((ShouldNotMatch4 和这个 @(ShouldMatch4))

• 匹配并捕获：
  • 应该匹配1
  • ShouldMatch2
  • ShouldMatch3
  • 应该匹配4

基本上，这里是要求：

• 如果它以 @ 开头，然后是 [a-zA-Z]+[0-9]* 那么我想匹配它。
• 如果它以 @( 开头，那么我只想匹配后面跟着 [a-zA-Z]+[0-9]* 然后是 ) 的情况。

这是我作为开始的内容，它在大部分情况下都有效，但它匹配 ShouldNotMatch2

\@[(]?([a-zA-Z]+[0-9]*[)]*)

Answer 1

如果您的正则表达式引擎支持条件：

@(\()?([A-Za-z]+[0-9]*)(?(1)\))

说明：

@           # Match @
(\()?       # Optionally match `(` and capture in group 1
(           # Match and capture in group 2
 [A-Za-z]+  # 1+ ASCII letters
 [0-9]*     # 0+ ASCII digits
)           # End of capturing group
(?(1)       # If group 1 participated in the match
 \)         # match a closing parenthesis
)           # End of conditional

Answer 2

此代码：

#!/usr/bin/env perl

$_ = <<'LA VISTA, BABY';  # the Terminator, of course :)
    This @ShouldMatch1 and this @ShouldMatch2 and this @((ShouldNotMatch1)andthis@ShouldMatch3) and this @(ShouldNotMatch2 an
d this @1ShouldNotMatch3 and this @((ShouldNotMatch4 and this @(ShouldMatch4))'
LA VISTA, BABY

print $+{id}, "\n" while m{
    @ (?: \(  (?<id> \pL+ \d* )  \)
        |     (?<id> \pL+ \d* )
      )
}gx;

运行时将打印出您想要的输出：

ShouldMatch1
ShouldMatch2
ShouldMatch3
ShouldMatch4

---

编辑

这是对先前解决方案从更简单到更精美的五个阶段的阐述。然而，目前还不清楚标识符的真正规则是什么或应该是什么。

1. 原始问题： \pL+\d* 这表示它以字母开头，然后可能以数字结尾，但并非必须如此。
2. \pL+\d+ 强制使用数字。
3. \pL[\pL\d]* 必须以字母开头，但允许字母和数字混合。
4. \pL\w* 为首字母后面的内容添加下划线。从技术上讲，根据 UTS#18 的 \w 应该是所有字母、所有标记、字母数字（如罗马数字）、所有十进制数字以及所有连接标点符号。
5. \w+ 适用于所有字母、数字或下划线，没有限制。这就是根据标准的单词字符。
6. (?=\pL)\w+(?<=\d) 添加了一个约束，即它必须以字母开头并以数字结尾，但否则可以是单词字符的组合。

无论实际需要哪一个（目前还不清楚），更新代码以使用适当的变体应该很容易，特别是在最后两个版本中，这些有趣的标识符的定义仅出现在一个地方代码。这样就可以轻松地在一处进行更改，并消除更新不一致的错误。程序员应该始终努力排除重复的代码，无论他们的编程语言如何，甚至正则表达式都是如此，因为抽象是良好设计的基础。

这是 5 路版本：

#!/usr/bin/env perl

$_ = <<'LA VISTA, BABY';  # the Terminator, of course :)
    This @ShouldMatch1 and this @ShouldMatch2 and this @((ShouldNotMatch1)andthis@ShouldMatch3) and this @(ShouldNotMatch2 and this @1ShouldNotMatch3 and this @((ShouldNotMatch4 and this @(ShouldMatch4))'
LA VISTA, BABY

$mask  = "Version %d: %s\n";
$verno = 0;

##########################################################
# Simplest version: nothing fancy
++$verno;
printf($mask, $verno, $+) while /\@(?:(\pL+\d*)|\((\pL+\d*)\))/g;
print "\n";

##########################################################
# More readable version: add /x for spacing out regex contents
++$verno;
printf($mask, $verno, $+) while / \@ (?: (\pL+\d*) | \( (\pL+\d*) \) ) /xg;
print "\n";

##########################################################
# Use vertical alignment for greatly improved legibility,
# plus named captures for convenience and self-documentation
++$verno;
printf($mask, $verno, $+{id}) while m{
    @ (?: \(  (?<id> \pL+ \d* )  \)
        |     (?<id> \pL+ \d* )
      )
}xg;
print "\n";

##########################################################
# Define the "id" pattern separately from executing it
# to avoid code duplication. Improves maintainability.
# Likely requires Perl 5.10 or better, or PCRE, or PHP.
++$verno;
printf($mask, $verno, $+)     while m{
    (?(DEFINE)  (?<id> \pL+ \d* )   )

    @ (?: \( ((?&id)) \)
        |    ((?&id))
      )
}xg;
print "\n";

##########################################################
# this time we use a named capture that is different from
# the named group used for the definttion.
++$verno;
printf($mask, $verno, $+{id}) while m{
    (?(DEFINE)  (?<word> \pL+ \d* )   )

    @ (?: \( (?<id> (?&word) ) \)
        |    (?<id> (?&word) )
      )
}xg;

当在 Perl v5.10 或更高版本上运行时，会适当地生成：

Version 1: ShouldMatch1
Version 1: ShouldMatch2
Version 1: ShouldMatch3
Version 1: ShouldMatch4

Version 2: ShouldMatch1
Version 2: ShouldMatch2
Version 2: ShouldMatch3
Version 2: ShouldMatch4

Version 3: ShouldMatch1
Version 3: ShouldMatch2
Version 3: ShouldMatch3
Version 3: ShouldMatch4

Version 4: ShouldMatch1
Version 4: ShouldMatch2
Version 4: ShouldMatch3
Version 4: ShouldMatch4

Version 5: ShouldMatch1
Version 5: ShouldMatch2
Version 5: ShouldMatch3
Version 5: ShouldMatch4

更新 id 的定义以匹配实际需要的内容应该很容易。

请注意，某些正则表达式引擎使指定属性变得非常麻烦。例如，它们可能需要 \p{L} 而不是普通的 \pL。这是他们设计错误的霍夫曼编码失败，因为你总是希望最常用的形式是最短的形式。由于 \pL 或 \pN 只比 \w 或 \d 长一个字符，因此人们更容易理解倾向于使用改进的版本，但像 \p{L} 和 \p{N} 这样的东西现在比 \w 长三个字符> 和 \d，加上启动时不必要的视觉混乱。您不必为了获得“正常”ᴀᴋᴀ 最常见的情况而支付三倍的费用。 :(

如果您要放入难看的大括号，那么您不妨将其完整写为 \p{Letter} 和 \p {Number} 毕竟，正如他们所说，“一分钱一分货”。

Answer 3

它是 @(foo1) 或 @foo1，因此请使用alternation:

@([a-zA-Z]+[0-9]|\([a-zA-Z]+[0-9]\))

并在第二步中去掉括号（简单的字符串替换）。