使用 perl tie::file 和 utf 编码文件

Question

我可以将 Tie::File 与 utf 编码的输出文件一起使用吗？我无法让它正常工作。 我想做的是打开这个 utf 编码的文件，从文件中删除匹配字符串并重命名该文件。

代码：

use strict;
use warnings;
use Tie::File;
use File::Copy;

my ($input_file) = qw (test.txt);

open my $infh, "<:encoding(UTF-16LE)", $input_file or die "cannot open '$input_file': $!";

for (<$infh>) {
    tie my @lines, "Tie::File", $_;
    shift @lines if $lines[0] =~ m/MyHeader/;
    untie @lines;
    my ($name) = /^(.*).csv/i;
    move($_, $name . ".dat");
}

close $infh
    or die "Cannot close '$input_file': $!";

代码：（已更新）

my ($input_file) = qw (test.txt);
my $qfn_in = $input_file;
my $qfn_out = $qfn_in . ".dat";

open(my $fh_in, "<:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_in)
   or die("Can't open \"$qfn_in\": $!\n");

open(my $fh_out, ">:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_out)
   or die("Can't open \"$qfn_out\": $!\n");

while (<$fh_in>) {
   next if $. == 1 && /MyHeader/; 
   print($fh_out $_)
      or die("Can't write to \"$qfn_out\": $!");
}

close($fh_in);
close($fh_out) or die("Can't write to \"$qfn_out\": $!");

rename($qfn_out, $qfn_in)
   or die("Can't rename: $!\n");

Answer 1

Tie::File perldoc 中对此进行了详细记录，但你想通过discipline =>;绑定文件时的 ':encoding(UTF-16LE)' 选项：

tie my @lines, 'Tie::File', $input_file, discipline => ':encoding(UTF-16LE)'

请注意，第三个参数是与绑定数组关联的文件的名称。 Tie::File 会自动为你打开并管理文件句柄；无需自己对文件调用open。

@lines 现在包含文件的内容，因此接下来要做的就是检查第一行：

if ($lines[0] =~ m/pattern/) {
    my $line = shift @lines;
    untie @lines;   # rewrites, closes the file, w/o first line
    my ($name) = $line =~ /^(.*).csv/i;
    rename $input_file, "$name.dat";
}

但我同意 TLP 的观点，Tie::File 对此来说太过分了工作。

（我之前关于使用正确的编码打开文件句柄并将 glob 作为第三个参数传递给 Tie::File 的答案将不起作用，因为（1）它没有在 read 中打开文件/write 模式，并且 (2) 即使这样做，Tie::File 也不能或不会对文件句柄的读取和写入应用编码）

Answer 2

my $qfn_in = ...;
my $qfn_out = $qfn_in . ".tmp";

open(my $fh_in, "<:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_in)
   or die("Can't open \"$qfn_in\": $!\n");

open(my $fh_out, ">:raw:perlio:encoding(UTF-16le):crlf:utf8", $qfn_out)
   or die("Can't open \"$qfn_out\": $!\n");

while (<$fh_in>) {
   next if $. == 1 && /MyHeader/;
   print($fh_out $_)
      or die("Can't write to \"$qfn_out\": $!");
}

close($fh_in);
close($fh_out) or die("Can't write to \"$qfn_out\": $!");

rename($qfn_out, $qfn_in)
   or die("Can't rename: $!\n");

（:perlio 和 :utf8 是当时存在的错误的解决方法。）

Answer 3

该行：

tie my @lines, "Tie::File", $_;

尝试将 @lines 绑定到一个文件，其中包含 test.txt 每行的名称。由于它似乎不是一个包含文件名的文件，我怀疑该 tie 失败了。

您可能想要在 test.txt 上使用 Tie::File。如果您只想检查该文件的第一行，则不需要循环。

所以你需要类似的东西：

use autodie;  #handy to check for fatal errors
tie my @lines, "Tie::File", $input_file;
shift @lines if $lines[0] =~ /MyHeader/;
untie @lines;
if ($input_file =~ /(.+).csv/i) {
    move($input_file, $1);
}

但是有更简单的方法来检查文件的第一行。这将检查一个文件：

perl -we '$_=<>; print if /MyHeader/; print <>;' test.txt > test.dat