在 Clojure 1.3 中，如何读写文件

Question

我想知道在 clojure 1.3 中读取和写入文件的“推荐”方式。

1. 如何读取整个文件
2. 如何逐行读取文件
3. 如何写入新文件
4. 如何向现有文件添加一行

Answer 1

假设我们在这里只处理文本文件，而不是一些疯狂的二进制文件。

第一：如何将整个文件读入内存。

(slurp "/tmp/test.txt")

当文件非常大时不推荐。

第二点：如何逐行读取文件。

(use 'clojure.java.io)
(with-open [rdr (reader "/tmp/test.txt")]
  (doseq [line (line-seq rdr)]
    (println line)))

with-open 宏负责确保读取器在正文末尾关闭。 reader 函数将字符串（也可以执行 URL 等）强制转换为 BufferedReader。 line-seq 提供了一个惰性序列。要求惰性序列的下一个元素会导致从读取器读取一行。

请注意，从 Clojure 1.7 开始，您还可以使用转换器来读取文本文件。

第三点：如何写入新文件。

(use 'clojure.java.io)
(with-open [wrtr (writer "/tmp/test.txt")]
  (.write wrtr "Line to be written"))

同样，with-open 会注意 BufferedWriter 在正文末尾关闭。 Writer 将字符串强制转换为 BufferedWriter，您可以通过 java 互操作使用该字符串：(.write wrtr "something")。

您还可以使用 spit >，与 slurp 相反：

(spit "/tmp/test.txt" "Line to be written")

数字 4：向现有文件追加一行。

(use 'clojure.java.io)
(with-open [wrtr (writer "/tmp/test.txt" :append true)]
  (.write wrtr "Line to be appended"))

与上面相同，但现在带有追加选项。

或者再次使用 spit，与 slurp 相反：

(spit "/tmp/test.txt" "Line to be written" :append true)

PS： 为了更明确地说明您正在读取和写入文件的事实，不是别的，您可以首先创建一个 File 对象，然后将其强制转换为 BufferedReader 或 Writer：

(reader (file "/tmp/test.txt"))
;; or
(writer (file "tmp/test.txt"))

文件函数也在 clojure.java.io 中。

PS2：有时能够很方便地查看当前目录（即“.”）是什么。您可以通过两种方式获取绝对路径：

(System/getProperty "user.dir") 

或者

(-> (java.io.File. ".") .getAbsolutePath)

Answer 2

如果文件适合内存，您可以使用 slurp 和 spit 读取和写入它：

(def s (slurp "filename.txt"))

（s 现在包含文件内容作为字符串）

(spit "newfile.txt" s)

如果它不退出并写入文件内容，则会创建 newfile.txt。
如果你想追加到文件中，你可以

(spit "filename.txt" s :append true)

按行读取或写入文件，你可以使用Java的读取器和写入器。它们被包装在命名空间 clojure.java.io 中：

(ns file.test
  (:require [clojure.java.io :as io]))

(let [wrtr (io/writer "test.txt")]
  (.write wrtr "hello, world!\n")
  (.close wrtr))

(let [wrtr (io/writer "test.txt" :append true)]
  (.write wrtr "hello again!")
  (.close wrtr))

(let [rdr (io/reader "test.txt")]
  (println (.readLine rdr))
  (println (.readLine rdr)))
; "hello, world!"
; "hello again!"

请注意，slurp/spit 和 reader/writer 示例之间的区别在于，后者中的文件保持打开状态（在 let 语句中），并且读取和写入被缓冲，因此重复读取/写入文件时效率更高。

以下是更多信息： slurp 吐
clojure.java.io
Java 的 BufferedReader
Java 的 Writer

Answer 3

关于问题 2，有时希望将行流作为第一类对象返回。为了将其作为惰性序列，并且仍然在 EOF 时自动关闭文件，我使用了以下函数：

(use 'clojure.java.io)

(defn read-lines [filename]
  (let [rdr (reader filename)]
    (defn read-next-line []
      (if-let [line (.readLine rdr)]
       (cons line (lazy-seq (read-next-line)))
       (.close rdr)))
    (lazy-seq (read-next-line)))
)

(defn echo-file []
  (doseq [line (read-lines "myfile.txt")]
    (println line)))

Answer 4

要逐行读取文件，您不再需要诉诸互操作：

(->> "data.csv"
      io/resource
      io/reader
      line-seq
      (drop 1))

这假设您的数据文件保存在资源目录中，并且第一行是可以丢弃的标头信息。

Answer 5

这是读取整个文件的方法。

如果该文件位于资源目​​录中，则可以执行以下操作：

(let [file-content-str (slurp (clojure.java.io/resource "public/myfile.txt")])

记住 require/use clojure.java.io。

Answer 6

(require '[clojure.java.io :as io])
(io/copy (io/file "/etc/passwd") \*out*\)