使用 Excel VBA 自动筛选时如何删除空白行

Question

我编写了一个宏，可以搜索工作簿并将自动筛选器应用于具有名为“Code”列的任何列表对象。但是，当我应用过滤器时，它不会过滤掉空白行。知道如何过滤掉这些吗？

下面是应用过滤器的代码：

Public Sub ApplyFilter(filter As Variant)
Dim wb As Workbook
Dim ws As Worksheet
Dim lo As ListObject

Set  wb = ActiveWorkbook

' Loop through each sheet in the workbook
For Each ws In wb.Sheets
    ' Find any listobjects within the sheet
    For Each lo In ws.ListObjects
        Dim r As Integer
        ' Find the column named Code and filter on this column
        r = lo.Range.Rows(1).Find("Code").Column
        ' Clear any existing filter
        lo.Range.AutoFilter Field:=r
        ' If the filter code is not "All Categories", 999, apply the filter
        If filter(0) <> 999 Then
            lo.Range.AutoFilter Field:=r, Criteria1:=filter, Operator:=xlFilterValues
        End If
    Next
Next

End Sub

传入的过滤器是一个数组，可能只有一个条件，也可能有多个条件。我也尝试添加 criteria2:=""，但这并没有改变任何东西。

如果您有任何想法，请告诉我。谢谢！

这是其他相关代码：

Public Sub FilterInvoice(filter As Range)
    Me.ApplyFilter Me.BuildFilter(filter)
End Sub

Public Function BuildFilter(filter As Range) As Variant
    Dim r As Range
    Dim arFilter() As String

    ' Get the cell of the current category
    Set r = Range("Categories").Find(filter.Value)

    ' Set the initial filter value to the category id
    ReDim Preserve arFilter(1)
    arFilter(0) = r.Offset(0, -1).Value

    ' Find any child categories, add child id's to filter array
    For c = 1 To Application.CountIf(Range("Categories").Columns(3), arFilter(0))
        Dim PrevChild As Range
        ' Expand the filter array
        ReDim Preserve arFilter(c + 1)
        If c = 1 Then
            Set PrevChild = Range("Categories").Columns(3).Find(arFilter(0))
        Else
            ' If it is not the first time through the loop, look for the next child after PrevChild
            Set PrevChild = Range("Categories").Columns(3).Find(arFilter(0), PrevChild)
        End If
        ' Offset the found child to get its code, add it to the filter array
        arFilter(c) = PrevChild.Offset(, -2)
    Next

    ' Add "<>" and "<900" to the criteria list to hide blank rows
    'ReDim Preserve arFilter(UBound(arFilter) + 2)
    'arFilter(UBound(arFilter) - 1) = "<>"
    'arFilter(UBound(arFilter)) = "<900"

    'Return the filter array
    BuildFilter = arFilter
End Function

Answer 1

如果您使用数组按多个条件进行过滤，则通过不包含“=”，自动过滤器应该过滤空白。例如，这不会过滤空白：

Criteria1:=Array("test", "2", "3", "4", "=")

如果失败，您可能需要使用特殊单元格（xlcelltypeblanks）手动隐藏它们。

编辑：

好吧，我想我可能让你对我的第一个解决方案感到困惑。我已经把它删除了。

现在我可以看到您的代码，我认为可能发生的情况是，当您循环遍历范围并添加条件时，您可能会添加一个空白单元格。一次一个地执行循环并确保情况并非如此。您可以添加此内容以显示过滤器并确保它不包含空格：

Debug.Print Join(arfilter, ",")

Answer 2

我知道这是一个老问题，但我在互联网上找不到任何令人满意的答案

所以我想分享一个似乎效果很好的解决方案：

ActiveSheet.Range("$A$1:$V$3000").AutoFilter Field:=ActiveSheet.Range("$A$1:$V$1").Find("Monitoring").Column, _
Criteria1:="<>Done", Operator:=xlFilterValues

空白单元格仍然存在，所以我们不需要将它们过滤掉

ActiveSheet.Range("$A$1:$V$1").Find("Monitoring").EntireColumn.SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = True

当然因为它使用 xlFilterValues，所以您也可以使用数组过滤器

ActiveSheet.Range("$A$1:$V$3000").AutoFilter Field:=ActiveSheet.Range("$A$1:$V$1").Find("Monitoring").Column, _
Criteria1:=Array( _
     "Department1", "Department2", "Department3", "Department4", _
    "Department5", "Department6", "="), Operator:=xlFilterValues

希望您喜欢！