在给定整数约束的 Mathematica 中简化积分结果的正确方法

Question

计算以下积分应该是非零，并且 mathematica 正确地给出非零结果

Integrate[ Cos[ (Pi * x)/2 ]^2 * Cos[ (3*Pi*x)/2 ]^2, {x, -1, 1}]

但是，尝试更一般的积分：

FullSimplify[
    Integrate[Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/2], 
              {x, -1, 1}], 
    Element[{m, n}, Integers]]

产生零，这对于 m = n = 1 来说绝对不正确

我期望有一个条件表达式。在计算积分之前，是否可以“告诉”mathematica 我对 m 和 n 的约束，以便它正确处理特殊情况？

Answer 1

虽然我迟到了，但到目前为止，还没有人给出完整的解决方案。

有时，在积分之前更好地理解被积函数是值得的。考虑一下，

ef = TrigReduce[
    Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/2]]/.
  Cos[a_] :> Cos[ Simplify[a, Element[{m,n}, Integers] ] ]

它返回

(2 Cos[(m - n) Pi x] + Cos[(1 + m - n) Pi x] + Cos[(1 - m + n) Pi x] + 
 Cos[(m + n) Pi x] + 2 Cos[(1 + m + n) Pi x] + Cos[(2 + m + n) Pi x] )/8

每个项的形式为 Cos[q Pi x] 和整数 q。现在，在 -1 到 1（其中 q 是整数）上积分 Cos[q Pi x] 时需要考虑两种情况：q == 0 和 q != 0。

情况q = 0：这是 Mathematica 在一般结果中遗漏的特殊情况，因为它意味着一个常数被积函数。 （当我手动执行此操作时，我也经常会错过它，因此 Mathematica 不完全是罪魁祸首。）因此，在本例中，积分为 2。

严格来说，这不是真的。当被告知在 -1 -1 上积分 Cos[ q Pi x ] 时x < 1，Mathematica 返回

2 Sin[ Pi q ]/( Pi q )

0，除非 q == 0。此时，该函数在严格意义上是未定义的，但 Limit[Sin[x]/x, q -> 0]==1。由于 q == 0 处的奇点是可移除，因此积分当 q -> 时，为 2 0 。所以，Mathematica 并没有错过它，它只是以一种无法立即识别的形式。

情况q != 0：由于Cos[Pi x]是周期性的，周期为2，因此Cos[q Pi x]的积分]从x == -1到x == 1将始终超过q个周期。换句话说，

Integrate[ Cos[q Pi x], {x, -1, 1}, 
  Assumptions -> (Element[ q, Integers ] && q != 0) ] == 0

综合起来，这意味着

Integrate[ Cos[q Pi x], {x, -1, 1}, Assumptions -> Element[ q, Integers ] ] == 
Piecewise[{{ q == 0, 2 }, { 0, q!=0 }}]

积分被积函数的扩展形式

intef = ef /. Cos[q_ Pi x] :> Piecewise[{{2, q == 0}, {0, q != 0}}] // 
 PiecewiseExpand 

使用它，我们可以通过它承认非积分解来 。为了解决这个问题，我们需要将条件减少到只有那些具有整体解决方案的条件，并且我们不妨简化一下：

(Piecewise[{#1, 
    LogicalExpand[Reduce[#2 , {m, n}, Integers]] // 
     Simplify[#] &} & @@@ #1, #2] & @@ intef) /. C[1] -> m

\begin{Edit}

为了限制混乱，在内部分段 具有以下结构：

{ { { value, condition } .. }, default }

在使用 Apply (@@) 中，条件列表是第一个参数，默认参数是第二个参数。为了处理这个问题，我需要简化每个值的条件，因此我使用第二种简短形式 Apply (@@@) 在条件列表上，以便对于每个值条件对我得到

{ value, simplified condition }

简化过程使用 Reduce 将条件限制为整数、LogicalExpand 帮助消除冗余，以及 Simplify 限制项数。 Reduce 内部使用 任意常量，C[1]，它设置为 C[1] == m，因此我们将 C[1] 设置回 m< /code> 完成简化

\end{Edit}

给出了

Piecewise[{
 {3/4, (1 + n == 0 || n == 0) && (1 + m == 0 || m == 0)},
 {1/2, Element[m, Integers] && 
       (n == m || (1 + m + n == 0 && (m <= -2 || m >= 1)))},
 {1/4, (n == 1 + m || (1 + n == m && (m <= -1 || m >= 1)) || 
       (m + n == 0 && (m >= 1 || m <= 0)) || 
       (2 + m + n == 0 && (m <= -1 || m >= 0))) && 
       Element[m, Integers]},
 {0, True}
}

完整的解决方案。

另一个编辑：我应该指出，1/2 和 1/4 情况都包含 3/ 中的 m 和 n 值4 例。看起来 3/4 的情况可能是其他两个的交集，因此也是它们的总和。 （我还没有计算出来，但我强烈怀疑这是真的。）Piecewise 按顺序评估条件（我认为），因此不可能出现错误。

再次编辑：分段对象的简化并没有达到应有的效率。问题在于替换规则 C[1] -> 的位置。米。 Simplify 恰好在这个过程的后期使用它。但是，如果将其引入 LogicalExpand 并将假设添加到 Simplify 中

(Piecewise[{#1, 
    LogicalExpand[Reduce[#2 , {m, n}, Integers] /. C[1] -> m] // 
     Simplify[#, {m, n} \[Element] Integers] &} & @@@ #1, #2] & @@ intef)

，则会产生更清晰的结果

Piecewise[{
 {3/4, -2 < m < 1 && -2 < n < 1}, 
 {1/2, (1 + m + n == 0 && (m >= 1 || m <= -2)) || m == n}, 
 {1/4, 2 + m + n == 0 || (m == 1 + n && m != 0) || m + n == 0 || 1 + m == n},
 {0, True}
}]

Answer 2

并不总是零...

k = Integrate[
         Cos[(Pi x)/2]^2 Cos[((2 (n) + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/ 2], 
         {x, -1, 1}, Assumptions -> Element[{m, n}, Integers]];

(*Let's find the zeroes of the denominator *)

d = Denominator[k];
s = Solve[d == 0, {m, n}]

(*The above integral is indeterminate at those zeroes, so let's compute 
  the integral again there (a Limit[] could also do the work) *)

denZ = Integrate[
          Cos[(Pi x)/2]^2 Cos[((2 (n) + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/ 2] /.s, 
          {x, -1, 1}, Assumptions -> Element[{m, n}, Integers]];

(* All possible results are generated with m=1 *)

denZ /. m -> 1

(*
{1/4, 1/2, 1/4, 1/4, 1/2, 1/4}
*)

可视化这些情况：

Plot[Cos[(Pi x)/2]^2 Cos[((2 (n) + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/2] 
     /. s /. m -> 1, {x, -1, 1}]

与零结果积分一进行比较：

Plot[Cos[(Pi x)/2]^2 Cos[((2 (n) + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/ 2] 
     /. {m -> 1, n -> 4}, {x, -1, 1}]

Answer 3

如果您只需删除整个 FullSimplify 部分，mathematica 就会为您巧妙地进行集成。

Integrate[
 Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/
    2], {x, -1, 1}]

包含 m 和 n 的条件是整数，最好使用Integrate中的Asminations选项。

Integrate[
 Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/
    2], {x, -1, 1}, Assumptions -> Element[{m, n}, Integers]]

Answer 4

让我们对两个整数使用一些结论性条件m=n||m!=n。

Assuming[{(n \[Element] Integers && m \[Element] Integers && m == n)},
Integrate[Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/2],
{x, -1, 1}]]

本例的答案是1/2。对于另一种情况

Assuming[{(n \[Element] Integers && m \[Element] Integers && m != n)},
Integrate[
Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/
 2], {x, -1, 1}]]

，答案是0。

然而，我惊讶地发现，如果我们将这两个条件添加为“非此即彼”，Mathematica 在积分后会返回一零。我的意思是，在以下情况下，我只会得到零，但不会得到“1/2||0”。

Assuming[{(n \[Element] Integers && m \[Element] Integers && 
 m == n) || (n \[Element] Integers && m \[Element] Integers && 
 m != n)}, 
Integrate[
Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/
 2], {x, -1, 1}]]

顺便说一句，我们可以看到该积分变为不确定的唯一条件。

res = Integrate[
Cos[(Pi x)/2]^2 Cos[((2 n + 1) Pi x)/2] Cos[((2 m + 1) Pi x)/
  2], {x, -1, 1}] // Simplify

输出在这里。

现在让我们看看 m 和 n 的所有关系> 可能不得不使 Integral 变坏！

BadPart = (res*4 Pi);
Flatten@(Solve[(Denominator[#] == 0), m] & /@ 
 Table[BadPart[[i]], {i, 1, Length@BadPart}] /. 
Rule -> Equal) // TableForm

因此，这些是特殊情况，正如 Sjoerd 提到的那样，它们具有无限实例。

BR