即使 SAS 中设置的数据集为空（零观测值），if _N_ = 1 条件也会返回 true

Question

对SAS的疑问：

    data new;
        set _NULL_;
    run;

   data _NULL_;
        set new;
        if _N_ = 0 then call execute ("%put empty dataset;");
        if _N_ = 1 then call execute ("%put non-empty dataset;");
   run;

根据我的理解，上面的代码应该只打印第一个注释，即空数据集。由于某种原因，它也为第二个 if 条件返回 true 并打印非空数据集。

请让我知道我哪里出了问题？

Answer 1

好吧，这就是我认为正在发生的事情。第一个问题是宏调用用双引号引起来，因此在 SAS 甚至开始处理数据步骤之前就由预处理器进行处理（无论 if 条件是否为真都执行）。您需要将要执行的参数放在单引号而不是双引号中，以防止宏预处理器过早执行它。

但是，此代码仍然无法在空数据集上运行，就像设置行上提供的数据集为空一样，整个数据步骤将在执行任何进一步的代码之前终止。

第三，_N_ 初始化为 1，而不是 0，并在数据步边界上从那里递增，因此 _N_ = 0 条件将始终为 false。

另一种解决方法是使用 nobs= 选项进行如下设置：

data _NULL_;
  if 0 then set new nobs=num_obs;
  if num_obs = 0 then call execute ('%put empty dataset;');
  if num_obs > 0 then call execute ('%put non-empty dataset;');
stop;
run;

if 0 then 是一个虚拟条件，用于强制执行数据步骤代码；如果使用裸集语句，则如果数据集“new”为空，则执行将不会继续经过设置行。

更好的选择可能是使用宏打开数据集并读取 ANY 属性：

%let dsid = %sysfunc (open(dataset_name));
%let anyobs = %sysfunc (attrn(&dsid,ANY));
%let dsid = %sysfunc (close(&dsid));

如果 dataset_name 包含至少一个观察值（行）和至少一个变量（列），如果它不包含观测值但至少有一个变量，则为 0；如果它不包含观测值且不包含变量，则为 -1。