Haskell - 调用类型类中定义的函数

Question

给定一个类型类：

class AnimalTrainer animal food where
    getFood :: animal -> (food, Int) -- Returns the food and the quantity
    feed :: animal -> (food, Int) -- Returns the leftovers

    feed a = feed' (getFood a) -- Provide a default implementation
        where feed' (f, n) = (f, n - 1)

和一个实例：

data Animal = Dog | Cat
data Food = Meat | Milk

instance AnimalTrainer Animal Food where
    getFood Dog = (Meat, 2)
    getFood Cat = (Milk, 3)

如何编写另一个函数（在其他地方）来调用类型类中定义的 feed 函数？示例：

feedEverything :: Bool
feedEverything = snd (feed Dog) == 0

谢谢

Answer 1

问题是 Haskell 无法弄清楚你想要使用什么类型的食物。它看到一个实例：

instance AnimalTrainer Animal Food

但也许在某个地方还有第二个实例......

instance AnimalTrainer Animal Poison

所以你需要告诉 Haskell 动物只获取食物，而不是其他东西，例如毒药。

解决方案 1：您可以使用函数依赖：

class AnimalTrainer animal food | animal -> food where
    ...

这告诉 Haskell 对于每种动物类型，它只会吃一种食物类型。

解决方案 2：您还可以使用类型系列。

class AnimalTrainer animal where
    type AnimalFood animal :: *
    getFood :: animal -> (AnimalFood animal, Int)
    feed :: animal -> (AnimalFood animal, Int)

    feed a = feed' (getFood a) -- Provide a default implementation
        where feed' (f, n) = (f, n - 1)

data Animal = Dog | Cat
data Food = Meat | Milk

instance AnimalTrainer Animal where
    type AnimalFood Animal = Food
    getFood Dog = (Meat, 2)
    getFood Cat = (Milk, 3)

我个人认为这个解决方案有点深奥，而且语法有点不太自然。但这个例子是人为的，所以为了完整性我将其包括在内。

解决方案 3：您可以在每次调用 feed 时添加显式类型注释。

feedEverything = snd ((feed :: Animal -> (Food, Int)) Dog) == 0