在vbscript中使用回调函数

Question

我试图

在调用 IUpdateSearcher::BeginSearch 如何将回调传递给 ISearchCompletedCallback::调用方法 ？

我对这一点一无所知：

• 我是否需要一个函数或子函数，或者这是一个带有调用方法的自定义对象（以及如何创建），
• 我需要如何传递回调
• ，这在vbscript中是否可能（如果不是的话是什么）下一步好吗？）

谢谢

Answer 1

VBscript 不能很好地处理回调。

我一直在使用 BeginSearch ，<一href="https://learn.microsoft.com/en-us/windows/win32/api/wuapi/nf-wuapi-iupdatedownloader-begindownload" rel="nofollow noreferrer">开始下载 和 BeginInstall 有一段时间，解决方案是使用 iUnknown 的任何对象后代，并在其余代码中忽略它。

您必须使用返回对象的 IsCompleted 属性 iSearchJob, iDownloadJob 或 iInstallationJob，在调用EndSearch、EndDownload或EndInstall完成操作之前验证操作是否已完成并检索有效结果。

您还应该实现一个超时功能，以便在每个操作运行时间过长时终止该操作。

这是一个有效的简单示例（使用 CScript 运行）：

Dim strChars
    strChars = "-+|+"
If InStr(LCase(WScript.FullName),"cscript.exe") = 0 Then 
    WScript.Echo "This script requires to be run using CScript.exe"    
    WScript.Quit
End If
Set objUpdateSearcher = CreateObject("Microsoft.Update.Session").CreateUpdateSearcher()
WScript.Echo "Searching for new updates ..."
Set objSearchJob = objUpdateSearcher.BeginSearch ("", WScript , vbNull)
Do Until objSearchJob.IsCompleted
    WScript.Sleep 200
    WScript.StdOut.Write GetProgress & vbCr
Loop
Set objSearchResult = objUpdateSearcher.EndSearch (objSearchJob)
If objSearchResult.ResultCode = 2 Then
    If objSearchResult.Updates.Count = 0 Then
        WScript.Echo "No new updates."
    ElseIf objSearchResult.Updates.Count = 1 Then
        WScript.Echo "A new update is available."
    Else 
        WScript.Echo objSearchResult.Updates.Count & " new updates available."
    End If
Else
    WScript.Echo "Error while searching updates (Code: 0x" & Hex(objSearchResult.ResultCode) & ")"
End If
Function GetProgress
    GetProgress = Left(strChars,1)
    strChars = Right(strChars,Len(strChars)-1) & Left(strChars,1)
End Function

Answer 2

我从未尝试过，但我会查看 ConnectObject 方法。
这篇关于脚本事件的文章可能也有用。

所以也许是这样的（完全猜测）：

Set objSession = CreateObject("Microsoft.Update.Session")
Set objSearcher = objSession.CreateUpdateSearcher
WScript.ConnectObject objSearcher, "searcherCallBack_"
objSearcher.BeginSearch ...


sub searcherCallBack_Invoke()
    ' handle the callback
end sub

我还建议阅读 异步 WUA 操作指南，以确保您自行清理。
该链接还提到使用 Windows Script Host，因此绝对可以做到这一点，尽管除非您需要异步，否则同步方法可能会更容易。