使用 FTP FileUpload 上传的零大小文件

Question

我最近阅读了大量关于 ASP.NET 中 FTP 上传的文章，它们似乎都很有道理，但每次我尝试实现它们时，我要么上传一个空文件，要么根本没有文件。以下是我读过的一些文章：

• 管理来自 ASP 的 FTP 传输.NET 网页 作者：John Peterson
• 文件上传控件没有给出完整路径......帮助!!!!
• 如何：使用 FileUpload Web 服务器控件上传文件< /a>

它们都是很棒的文章，但就像我说的，有问题:(

我确切地知道问题是什么，但我不知道如何解决它。我可以从 FileUpload 控件传递文件名，但是出于安全考虑，该路径不存在。但是，StreamReader 对象需要上传文件的完全限定路径，所以我到底如何得到它

？使用我上面链接的约翰彼得森的例子。这是代码：

Protected Sub btnUploadFile_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    Dim myFtpWebRequest As FtpWebRequest
    Dim myFtpWebResponse As FtpWebResponse
    Dim myStreamWriter As StreamWriter

    myFtpWebRequest = WebRequest.Create("ftp://ftp_server_name/filename.ext")
    myFtpWebRequest.Method = WebRequestMethods.Ftp.UploadFile
    myFtpWebRequest.UseBinary = True

    myStreamWriter = New StreamWriter(myFtpWebRequest.GetRequestStream())

    'IT BREAKS HERE BECAUSE THE CLIENT PATH IS WRONG!!
    myStreamWriter.Write(New StreamReader(Server.MapPath("filename.ext")).ReadToEnd)
    myStreamWriter.Close()

    myFtpWebResponse = myFtpWebRequest.GetResponse()
    myFtpWebResponse.Close()
End Sub

看到了吗？上传的文件中没有数据:(

现在我最新的实现看起来像这样，但是上传的文件多了比源更大，而且严重损坏，我到底做错了什么？我已经花了两天时间了，

Protected Sub btnUploadFile2_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    Dim myFtpWebRequest As FtpWebRequest
    Dim myFtpWebResponse As FtpWebResponse

    filename = Path.GetFileName(FileUpload1.FileName)

    myFtpWebRequest = CType(WebRequest.Create(ftpServer + ftpPath + filename), FtpWebRequest)
    myFtpWebRequest.Method = WebRequestMethods.Ftp.UploadFile
    myFtpWebRequest.UseBinary = True

    'NEW APPROACH USING THE STREAM OF THE FILE FROM THE FileUpload Control
    'CORRECT BYTE LENGTH - in sourceStream.BaseStream
    Dim sourceStream As New StreamReader(FileUpload1.FileContent)
    'WRONG BYTE LENGTH - in sourceStream.ReadToEnd()
    Dim fileContents As Byte() = Encoding.UTF8.GetBytes(sourceStream.ReadToEnd())
    sourceStream.Close()
    myFtpWebRequest.ContentLength = fileContents.Length

    Dim requestStream As Stream = myFtpWebRequest.GetRequestStream()
    requestStream.Write(fileContents, 0, fileContents.Length)
    requestStream.Close()

    myFtpWebResponse = CType(myFtpWebRequest.GetResponse(), FtpWebResponse)
    myFtpWebResponse.Close()
End Sub

非常感谢 Adam Maras 的惊人回答，我会留下我的错误。这里是为了其他人受益于找到此线程的人；）

Answer 1

首先，如果您要像这样使用 ASP.NET，您必须通过网络服务器上传。如果不在客户端浏览器上安装插件或使用 ActiveX 控件（或类似控件），您绝对无法直接从客户端计算机上传到 FTP 服务器。

我假设您正在上传二进制文件；如果是这种情况，您使用 StreamReader 和 StreamWriter 的方式可能会损坏文件的二进制内容。相反，我们可以使用 Stream.CopyTo 将数据逐字从一个流移动到另一个流的方法。

我已经修改了您的方法以使用此模式：

Protected Sub btnUploadFile2_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    Dim myFtpWebRequest As FtpWebRequest
    Dim myFtpWebResponse As FtpWebResponse

    filename = Path.GetFileName(FileUpload1.FileName)

    myFtpWebRequest = CType(WebRequest.Create(ftpServer + ftpPath + filename), FtpWebRequest)
    myFtpWebRequest.Method = WebRequestMethods.Ftp.UploadFile
    myFtpWebRequest.UseBinary = True

    Dim myFileStream As Stream = FileUpload1.FileContent
    myFtpWebRequest.ContentLength = myFileStream.Length

    Dim requestStream As Stream = myFtpWebRequest.GetRequestStream()
    myFileStream.CopyTo(requestStream)
    requestStream.Close()

    myFtpWebResponse = CType(myFtpWebRequest.GetResponse(), FtpWebResponse)
    myFtpWebResponse.Close()
End Sub

Answer 2

FileUpload.SaveAs() 方法保存到Web 服务器的本地文件系统，并且无法写入 URI 或 FTP 站点。为此，您需要创建一个 WebRequest。

请参阅此处有关 FileUpload 控件的 MSDN 参考： http://msdn.microsoft.com/en-us/library/system.web.ui.webcontrols.fileupload.saveas.aspx

以及此处 WebRequest 的 FTP 使用：http://msdn.microsoft.com/en-us/library/ms229715.aspx

---

请注意 FileUpload 文档中给出的示例保存到 c:\temp\uploadedfiles。我建议您使用 Path.GetTempFileName() 来代替，因为这保证为您提供一个无论您在什么环境下都可以始终写入的文件。

Answer 3

数据会被损坏，因为您将文件当作文本来读取，但事实并非如此。

使用 BinaryReader 而不是 StreamReader，以便您可以直接以字节形式读取数据：

Dim fileContents As Byte()
Using sourceStream As New BinaryReader(FileUpload1.FileContent)
  fileContents = sourceStream.ReadBytes(Int32.MaxValue)
End Using