更新列表的值

Question

我有以下设置：

1> rd(rec, {name, value}).
rec
2> L = [#rec{name = a, value = 1}, #rec{name = b, value = 2}, #rec{name = c, value = 3}].
[#rec{name = a,value = 1},
 #rec{name = b,value = 2},
 #rec{name = c,value = 3}]
3> M = [#rec{name = a, value = 111}, #rec{name = c, value = 333}].
[#rec{name = a,value = 111},#rec{name = c,value = 333}]

列表 L 中的元素根据其 name 是唯一的。我也不知道列表 M 中元素的先前值。我想做的是用列表 M 中的值更新列表 L ，同时保留 L 中不存在的元素M。我做了以下工作：

update_values([], _M, Acc) ->
    Acc;
update_attributes_from_fact([H|T], M, Acc) ->
    case [X#rec.value || X <- M, X#rec.name =:= H#rec.name] of
      [] ->
        update_values(T, M, [H|Acc]);
      [NewValue] ->
        update_values(T, M, [H#rec{value = NewValue}|Acc])
    end.

它完成了这项工作，但我想知道是否有一种使用 bifs 的更简单的方法。

多谢。

Answer 1

没有现有的函数可以为您执行此操作，因为您只想更新值字段而不是替换 L 中的整个记录​​（如lists:keyreplace() 所做的那样）。如果 L 和 M 都可以很长，我建议如果可以的话，使用 #rec.name 作为键将 L 从列表更改为 dict 或 gb_tree。然后，您可以循环 M，对于 M 中的每个元素，查找正确的条目（如果有）并写回更新的记录。循环可以写成折叠。即使您先将列表 L 转换为字典，然后在循环后再次将其转换回来，它也会比 L*M 方法更有效。但是，如果 M 总是很短，并且您不想在代码的其余部分中将 L 作为字典保留，那么您当前的方法很好。

Answer 2

纯列表理解解决方案：

[case [X||X=#rec{name=XN}<-M, XN=:=N] of [] -> Y; [#rec{value =V}|_] -> Y#rec{value=V} end || Y=#rec{name=N} <- L].

使用 lists:keyfind/3 更有效：

[case lists:keyfind(N,#rec.name,M) of false -> Y; #rec{value=V} -> Y#rec{value=V} end || Y=#rec{name=N} <- L].

对于大 M 更有效：

D = dict:from_list([{X#rec.name, X#rec.value} || X<-M]),
[case dict:find(N,D) of error -> Y; {ok,V} -> Y#rec{value=V} end || Y=#rec{name=N} <- L].

但对于真正的大 M，这种方法可能是最快的：

merge_join(lists:keysort(#rec.name, L), lists:ukeysort(#rec.name, M)).

merge_join(L, []) -> L;
merge_join([], _) -> [];
merge_join([#rec{name=N}=Y|L], [#rec{name=N, value=V}|_]=M) -> [Y#rec{value=V}|merge_join(L,M)];
merge_join([#rec{name=NL}=Y|L], [#rec{name=NM}|_]=M) when NL<NM -> [Y|merge_join(L,M)];
merge_join(L, [_|M]) -> merge_join(L, M).

Answer 3

您可以使用 lists:uke​​ymerge/3：

lists:ukeymerge(#rec.name, M, L).

其中：

返回通过合并 TupleList1 和 TupleList2 形成的排序列表。
对每个元组的第 N 个元素执行合并。两个都
TupleList1 和 TupleList2 必须先进行键排序，不得重复
来评估这个函数。当两个元组比较相等时，元组
从 TupleList1 中选择并从 TupleList2 中删除。

记录是一个元组，您可以使用#rec.name 以透明的方式返回键的位置。请注意，我恢复了列表 L 和 M，因为该函数保留了第一个列表中的值。