批量递归动态变量的返回值

Question

我试图在延迟变量扩展中使用动态变量来表示其他动态变量。我遇到了一些麻烦。如果动态变量的值是另一个具有其自身值的动态变量，如何获取动态变量的值？

即！valA！ = %valB% = this

@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
...
...
FOR /F ... %%G IN (...) DO (
    SET _temp=%%~nG
    SET _file=!_temp:~0,-4!
    SET _cnt=0
    FOR /F ... %%L IN (...) DO (
        SET _temp=%%L
        SET _str=!_temp:*: =!
        SET /A _cnt+=1
        SET _temp=x!_file!!_cnt!
        IF DEFINED !_temp! (
            SET _temp=!%_temp%!
::
::_temp('s value) is _var('s value) is "xyz"
::Set new _temp to equal current _temp's "xyz"
::
            IF !_temp! NEQ !_str! (
                ECHO File Content Mismatch
            )
        ) ELSE (
            SET xvar=!_temp!
            SET !xvar!=!_str!
        )

    )
)
...
...
exit

如有任何帮助，我们将不胜感激。

Answer 1

从逻辑上讲，您的失败代码等同于

setlocal enableDelayedExpansion
(
  set VAR1=success
  set VAR2=VAR1
  set VAR3=!%VAR2%!
  echo VAR3=!VAR3!
)

正如之前的答案和评论中已经指出的那样，您无法为 VAR2 分配一个值，然后在同一代码块中使用 %VAR2% 访问该值，因为 %VAR2% 在解析过程中被扩展代码块的阶段，此时该值不是您想要的（可能未定义）。

但除了!VAR2! 之外，您还需要第二级扩展。得到你想要的结果。我知道三种解决方案。

1) 此解决方案可行，但不推荐，因为它很慢。

setlocal enableDelayedExpansion
(
  set VAR1=success
  set VAR2=VAR1
  call set VAR3=%%!VAR2!%%
  echo VAR3=!VAR3!
)

在执行 CALL 之前，每个 %% 都会减少为 %，并且 !VAR2!变为VAR1。
这样被调用的语句就变成了set VAR3=%VAR1%，并且被调用的语句通过%var%扩展阶段被重新解析，这样你就得到了你想要的结果。

但是 - CALL 相对非常昂贵。当在循环中使用时，可能会导致严重的性能下降。 jeb 在 打电话给我，或者更好地避免打电话

1a) CALL 解决方案有一种变体，您可以调用 :LABELed子程序。因为子例程是在调用后解析的，所以您可以简单地使用set VAR3=!%VAR2%!。但同样，这使用了 CALL，因此相对较慢，不推荐。

2) 这个通用解决方案有效，并且相比之下速度快得多。它使用 FOR 变量进行第二级扩展。这是推荐的解决方案。

setlocal enableDelayedExpansion
(
  set VAR1=success
  set VAR2=VAR1
  for /f %%A in ("!VAR2!") do set VAR3=!%%A!
  echo VAR3=!VAR3!
)

3) 如果已知 VAR1 的值是整数，则有一个使用 SET /A 的特殊情况解决方案

setlocal enableDelayedExpansion
(
  set VAR1=999
  set VAR2=VAR1
  set /a VAR3=!VAR2!
  echo VAR3=!VAR3!
)

SET /A 命令有其自己的内置扩展延迟扩展后发生的变量，不需要标点符号。

Answer 2

您的代码在 SET _temp=!%_temp%! 处失败，因为在解析括号块时会评估百分比扩展。

你可以把它改成顺便说

set "varname=!_temp!"
set "content=!varname!"

一句。如果您的示例可以减少到最少的代码，那么事情就会容易得多。

setlocal EnableDelayedExpansion
set "var1=content of var1"
set "var2=var1"
set "result=!%var2%!"
echo !result!

仅当它不在括号中时才有效。

为了更好地了解不同扩展的工作原理，
您可以阅读 Windows 命令如何解释器（CMD.EXE）解析脚本？