表示集合中类似表格的数据的最佳方式

Question

我认为我的问题是一个经典问题，但我无法找到实施解决方案的正确方法。所以我会在SOF这里问这个问题。

我需要将一些数据导出到 CSV 文件，其中包含标题和值（例如表格）。为了获取数据，我需要迭代集合。集合中的每个项目都有一个属性，其中包含键/值对的集合。密钥包含标头。并非每个键/值对集合都具有相同的大小。

当迭代键/值对时，我收集集合中所有可能的标头。当您到达其他键/值集合并且发现未知键时，该集合将被扩展。发生这种情况时，您需要确保相应的值将写入 CSV 文件的正确标题下。我试图使用标头集合中标头的索引，但我似乎无法让它工作。我考虑过多维数组、锯齿状数组以及与字典的几种组合。

对于我的解决方案，我不想在寻找正确的列时在标题和键之间进行字符串比较。这似乎没有必要。我认为两个循环和索引应该可以做到。

好的，这是我到目前为止的代码。这仅适用于外循环中的 1 项，因为 ArrayList 一次仅消耗一项，而不是任何给定的索引。当在外循环中的索引 12 处添加标头集合的新项目时，循环的值集合还没有索引 12。所以我的索引超出了范围。所以我想用标题数组列表的大小创建一个值数组列表，但这也不起作用。

Private Shared Function GetData(listItems As SPClient.ListItemCollection) As ArrayList
        'first store all values and make sure keys and values are matched
        Dim resultsToStore As ArrayList = New ArrayList()
        Dim headersToStore As ArrayList = New ArrayList()
        resultsToStore.Add(headersToStore)
        Dim totalListItems = listItems.Count
        Dim fieldNotToStore = ConfigurationService.FieldValuesNotToStore
        Dim displaynames = ConfigurationService.FieldValueDisplayNames

        For index As Integer = 0 To totalListItems - 1
            Dim valuesToStore As ArrayList = New ArrayList()
            Dim item As SPClient.ListItem = listItems(index)
            Dim fieldValues = item.FieldValues

            For Each fieldValue In fieldValues
                If (Not fieldNotToStore.Contains(fieldValue.Key)) Then 'If it is not in this collection is must be stored
                    Dim headerIndex = headersToStore.IndexOf(fieldValue.Key) 'does this key exist in the headersArray
                    If (headerIndex = -1) Then 'If fieldValue.Key is already in the array it doesn't need to be stored again (-1 = no index found)
                        Dim displayname = String.Empty
                        If (displaynames.ContainsKey(fieldValue.Key)) Then
                            displayname = displaynames.Item(fieldValue.Key)
                        Else
                            displayname = fieldValue.Key.ToString
                        End If
                        headerIndex = headersToStore.Add(displayname) '' Add new header
                    End If
                    valuesToStore.Insert(headerIndex, fieldValue.Value.ToString) 'use headerindex to match key an value
                End If
            Next
            resultsToStore.Add(valuesToStore) 
        Next
        Return resultsToStore
    End Function

我认为这个问题已经解决了一千次了，所以请友善。

更新：如果您有 vb.net 以外的任何其他（主流）语言的答案，那也没关系，但我更喜欢 vb.net 和 C#，因为它们都在 .net 框架上。

谢谢

Answer 1

首先，我认为你应该将你的函数分成更小的块。其次，你应该问自己，当你有泛型可以玩和使用时，为什么你仍然使用 ArrayList。

您似乎将数组列表存储在数组列表中，这已经表明您需要一个类，然后是该类的列表，例如

Public Class ValueStore
  Public Property Index as Integer
  Public Property FieldValue as String
End Class

您可以拥有一个像这样的类 ResutlStore

Public Class ResultStore
  Public ReadOnly Property ValueStores as Ilist(Of ValueStore)
  Public Sub New()
    ValueStores = new List(Of ValueStore)
  End Sub
  Public Sub AddValueStore(Byval Index as Integer, FieldValue as Integer)
    ValueStores.Add(new ValueStore() With {.Index = Index, .FieldValue = FieldValue})
  End Sub
End Class

之后，您执行一些提取方法

例如，您可以踢掉整个事情 像这样进入它自己的方法

Dim headerIndex = headersToStore.IndexOf(fieldValue.Key) 'does this key exist in the headersArray
If (headerIndex = -1) Then 'If fieldValue.Key is already in the array it doesn't need to be stored again (-1 = no index found)
    Dim displayname = String.Empty
    If (displaynames.ContainsKey(fieldValue.Key)) Then
        displayname = displaynames.Item(fieldValue.Key)
    Else
        displayname = fieldValue.Key.ToString
    End If
    headerIndex = headersToStore.Add(displayname) '' Add new header
End If

。

Private Shared Function HeaderIndex(Byval fieldvaluekey as object) as integer
    Dim displaynames = ConfigurationService.FieldValueDisplayNames
    Dim headerIndex = headersToStore.IndexOf(fieldValue.Key) 'does this key exist in the headersArray
      If (headerIndex = -1) Then 'If fieldValue.Key is already in the array it doesn't need to be stored again (-1 = no index found)
        Dim displayname = String.Empty
        If (displaynames.ContainsKey(fieldValue.Key)) Then
          displayname = displaynames.Item(fieldValue.Key)
        Else
          displayname = fieldValue.Key.ToString
        End If
        headerIndex = headersToStore.Add(displayname) '' Add new header
      End If
      return headerIndex
  End Function

这已经使你的函数更具可读性

Private Shared Function GetData(listItems As SPClient.ListItemCollection) As ArrayList
        'first store all values and make sure keys and values are matched
        Dim resultsToStore As ArrayList = New ArrayList()
        Dim headersToStore As ArrayList = New ArrayList()
        resultsToStore.Add(headersToStore)
        Dim totalListItems = listItems.Count
        Dim fieldNotToStore = ConfigurationService.FieldValuesNotToStore

        For index As Integer = 0 To totalListItems - 1
            Dim valuesToStore As ArrayList = New ArrayList()
            Dim item As SPClient.ListItem = listItems(index)
            Dim fieldValues = item.FieldValues

            For Each fieldValue In fieldValues
                If (Not fieldNotToStore.Contains(fieldValue.Key)) Then 'If it is not in this collection is must be stored
                    valuesToStore.Insert(headerIndex(fieldValue.Key), fieldValue.Value.ToString) 'use headerindex to match key an value
                End If
            Next
            resultsToStore.Add(valuesToStore) 
        Next
        Return resultsToStore
    End Function

Answer 2

首先，我要感谢 Chrissie1 激励我找到答案。对于其他人，这是我的解决方案。

首先，我创建了一个类来表示结果 csv 文件中的每一行。

Public Class MetaDataValue
     Inherits SortedDictionary(Of Integer, String)

     ''' <summary>
     ''' creates a comma seperated string of all data
     ''' </summary>
     ''' <returns></returns>
     ''' <remarks></remarks>
     Public Overrides Function ToString() As String
           ' some code to create a comma separated string of all data contained in the sorted    dictionary
     End Function
End Class

我使用了排序字典，因为它对整数键上的所有数据进行排序。这样您就可以确保所有数据都在索引上排序。此外，使用字典提供了一种将数据添加到集合中而不会出现索引越界错误的方法。

之后，您需要一种方法来收集所有元数据值。所以我创建了一个类：

''' <summary>
''' This class respresents a listItemCollection as provided in the constructor as table like data with headers and rows
''' </summary>
''' <remarks></remarks>
Public Class MetadataValuesFactory
    Private _fieldsNotToStore As List(Of String) = ConfigurationService.FieldValuesNotToStore
    Private _headers As MetaDataValue = New MetaDataValue()
    Private _rows As IList(Of MetaDataValue) = New List(Of MetaDataValue)

    ''' <summary>
    ''' returns a metaDAtvaleu object that contains all header values
    ''' </summary>
    ''' <returns></returns>
    ''' <remarks></remarks>

    Public Function GetHeaders() As MetaDataValue
        Dim result As MetaDataValue = New MetaDataValue()
        Dim displaynames = ConfigurationService.FieldValueDisplayNames
        For Each item In Me._headers
            Dim displayname = String.Empty
            If (displaynames.ContainsKey(item.Value)) Then
                result.Add(item.Key, displaynames.Item(item.Value))
            Else
                result.Add(item.Key, item.Value)
            End If
        Next
        Return result
    End Function

    ''' <summary>
    ''' Returns all rows that represent the values
    ''' </summary>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function GetRows() As IList(Of MetaDataValue)
        Return _rows
    End Function

    ''' <summary>
    ''' Creates a new metadatavaluesstore with the specified values
    ''' </summary>
    ''' <param name="listItems"></param>
    ''' <remarks></remarks>

    Sub New(listItems As ListItemCollection)
        'first store all values and make sure keys and values are matched
        Dim totalListItems = listItems.Count

        For index As Integer = 0 To totalListItems - 1
            Dim valuesToStore As MetaDataValue = New MetaDataValue()
            Dim item As SPClient.ListItem = listItems(index)
            Dim fieldValues = item.FieldValues

            For Each fieldValue In fieldValues
                If (Not _fieldsNotToStore.Contains(fieldValue.Key)) Then 'If it is not in this collection is must be stored
                    'Get index of field in _headers
                    Dim headerindex As Integer = _headers.Values.ToList().IndexOf(fieldValue.Key.ToString)
                    If (headerindex = -1) Then 'If fieldValue.Key is already in the array it doesn't need to be stored again (-1 = no index found)
                        'If Not exists then store header/key in _headers ánd set previous index to index of new headers value
                        headerindex = _headers.Count '' Add new header
                        _headers.Add(headerindex, fieldValue.Key.ToString)
                    End If
                    'add value to valuesstore
                    Dim valueToStore As String
                    If (fieldValue.Value Is Nothing) Then
                        valueToStore = String.Empty
                    Else
                        valueToStore = fieldValue.Value.ToString
                    End If
                    valuesToStore.Add(headerindex, valueToStore)
                End If
            Next
            _rows.Add(valuesToStore)
        Next
 End Sub
 End Class

注意，我将其称为工厂，我不太确定这是使用此模式的正确方法。但它不能是一个（普通）模型，因为此代码使用配置服务。你也不能真正称其为服务，所以我选择了工厂。

使用这两个类，您可以更轻松地使用工厂中包含的数据。例如，在我原来的解决方案中，我更改了显示名称的一些值。就像 Chrissie1 建议的那样，这可以重构。正如您所看到的，我现在在获取所有标头的方法中执行此操作。这样就有点晚了；在内部使用原始值，而在外部仅显示工厂允许的值。这样，该逻辑就包含在工厂内。如果将来某个时候需要一些新功能，则可以轻松单独访问标头和值。

编写 CSV 文件的代码现在更容易理解了：

metaDataStreamWriter.WriteLine(metadataFactory.GetHeaders.ToString)
For Each storeValue In metadataFactory.GetRows
     metaDataStreamWriter.WriteLine(storeValue.ToString)
Next

无论如何，这解决了我的问题。再次非常感谢您提供反馈并吸取教训。如果您有什么意见请提出。