在 Prolog 中删除 List L 的最后 3 个元素以生成 List L1

Question

我如何编写一个目标，从列表 L 中删除最后三个元素，生成另一个列表 L1？

另外，我将如何编写多个目标来从生成 L2 的列表 L 中删除前三个元素和最后三个元素？

Answer 1

Prolog 与其他语言有点不同，但它也有一个值得学习的库（标准 ISO）：

delete_last_3(L, L1) :-  
 append(L1, [_,_,_], L).

现在另一个请求就很容易了：

delete_first_and_last_3(L, L2) :-  
  append([_,_,_], LT, L), delete_last_3(LT, L2).

测试：

?- delete_last_3([1,2,3,4,5,6,7],X).
X = [1, 2, 3, 4] .

?- delete_first_and_last_3([1,2,3,4,5,6,7,8,9],L).
L = [4, 5, 6] .

Answer 2

您可能想尝试这样的操作：

without_last_three([_,_,_], []).
without_last_three([Head|Tail], [Head|NTail]):-
  without_last_three(Tail, NTail).

without_three_sides([_,_,_|L], L2):-
  without_last_three(L, L2).

第一个谓词将返回一个没有最后三个元素的列表，如果元素少于三个，则失败。

第二个谓词将返回一个没有前三个元素和最后三个元素的列表，如果元素少于六个则失败。

Answer 3

逻辑编程的第一步，从基本情况开始。当元素少于三个时你希望发生什么？我猜你想要一个空列表？

without_last_three([], []).
without_last_three([_], []).
without_last_three([_,_], []).
without_last_three([_,_,_], []).

现在，对于包含三个以上元素的列表，您希望保留第一个元素，并从其余元素中删除三个元素。您可能首先尝试编写：

without_last_three([A|L], [A|M]) :- without_last_three(L, M). !!wrong

但这会由于回溯而导致错误的结果。解决这个问题的最简单方法是验证 L 是否具有三个以上元素：

without_last_three([A,B,C,D|L], [A|M]) :- without_last_three([B,C,D|L], M).

但更优雅的解决方案是使用 Prolog 的 cut 运算符：

without_last_three([A|L], [A|M]) :- !, without_last_three(L, M).

要实现 without_first_third，又不会感到无聊，您可以简单地反转列表，删除最后三个，然后再翻回来：

without_first_three(I, O) :- reverse(I, A), without_last_three(A, B), reverse(B, O).

或者你可以写下一些非常简单的规则：（

without_first_three([], []).
without_first_three([_], []).
without_first_three([_,_], []).
without_first_three([_,_,_|L], L).

想一想，也许用 without_first_third 来实现 without_last_third 会更好，而不是相反）！