使用 Applescript 取消最小化应用程序

Question

我正在尝试编写一个脚本来取消最小化之前最小化到停靠的应用程序。 问题是，我找不到相关的属性。我尝试过小型化和折叠，但窗口和进程似乎都没有这些？

我使用（用于测试）的应用程序是 Zipeg，一个免费的打包​​工具。

我还尝试单击按钮，该按钮可以愉快地最小化应用程序，但在已经最小化的应用程序上运行以恢复它时给我一个错误，可能是因为没有窗口可见。该脚本如下。

tell application "System Events"
    tell process "Zipeg"
        click button 1 of window 1
    end tell
end tell

我用来列出属性的脚本如下。

tell application "System Events"
    tell process "Zipeg"
        get properties
        tell window 1
            get properties
        end tell
    end tell
end tell

有什么想法吗？

Answer 1

tell app (path to frontmost application as text)
    try
        set miniaturized of windows to false -- most apps
    end try
    try
        set collapsed of windows to false -- Finder
    end try
end tell

如果未选中最小化窗口到应用程序图标，则这将取消最小化单个窗口：

try
    tell app "System Events" to tell process "Dock"
        click (last UI element of list 1 where role description is "minimized window dock item")
    end tell
end try

如果应用程序的所有窗口都最小化，重新打开将取消最小化第一个窗口：

tell app "TextEdit"
    reopen -- unminimizes the first minimized window or makes a new default window
    activate -- makes the app frontmost
end tell

Answer 2

如果您告诉应用程序“App”激活，如果所有窗口都最小化，它将取消最小化窗口。

Answer 3

这应该适合你：

tell application "Safari"
    activate
    set index of window 1 to 1
end tell

Answer 4

尝试沿着这些思路做一些事情。

tell application "Finder" to set collapsed of every window to false

Answer 5

这是一个取消最小化当前聚焦的应用程序先前最小化窗口的脚本。

tell application id ("com.apple.systemevents")  ¬
  to tell (process 1 where it is frontmost) ¬
  to tell (windows whose attribute named "AXMinimized"'s value is true) ¬
  to if (it exists) then set the value of its attribute named "AXMinimized" of item 1 to false

我发现这个脚本比接受的答案更有用。

这个脚本不是我写的，你可以找到更多相关脚本这里。