重写 GetHashCode 变体

Question

我有一个理论类 Name_Order，它有一个字符串 Name 和一个 int Order。

我需要指出，如果 NameOrder 对不同，即名称或顺序不同，则两个 Name_Order 是不同的。

现在，覆盖 Equals 没有问题，但我对 GetHashCode 有一些“问题”：

Public Class Name_Order
  Public Property Name As String
  Public Property Order As Integer

  Public Overrides Function Equals(ByVal obj As Object) As Boolean
    If TypeOf obj Is Name_Order Then
      Dim no = DirectCast(obj, Name_Order)
      Return Me.Name = no.Name AndAlso Me.Order = no.Order
    Else
      Return MyBase.Equals(obj)
    End If
  End Function

  Public Overrides Function GetHashCode() As Integer
    Dim hcName = 0
    If Me.Name IsNot Nothing Then
      hcName = Me.Name.GetHashCode
    End If

    Dim hcOrder = Me.Order.GetHashCode

    Return hcName + hcOrder
  End Function
End Class

在这种情况下，对哈希码求和，留下两个不同名称或顺序的不同 Name_Orders 的（小但真实）可能性是“相同的”。

比如说，添加 7 + 154 与添加 154 + 7 得到的结果相同...

另一种覆盖那个方法？

Answer 1

首先，虽然避免碰撞固然很好，但如果发生碰撞也不是问题。但常见的方法是这样的：

return 7 * x.GetHashCode() + y.GetHashCode();

这在例如点/位置中更为明显，最好避免明显的对角线碰撞，例如 (2,3) 与 (3,2)。

代码中的一个更大问题是 hash/equals 中的属性是可变的；如果它们发生变化，字典等中的任何用法都将停止工作。您应该更喜欢只读键值。

Answer 2

MSDN 在这里给出了该情况的答案的变体（在示例部分）：

http ://msdn.microsoft.com/en-us/library/bb338049.aspx

Public Class Product
    Public Property Name As String
    Public Property Code As Integer
End Class

' Custom comparer for the Product class
Public Class ProductComparer
    Implements IEqualityComparer(Of Product)

    Public Function Equals1(
        ByVal x As Product, 
        ByVal y As Product
        ) As Boolean Implements IEqualityComparer(Of Product).Equals

        ' Check whether the compared objects reference the same data.
        If x Is y Then Return True

        'Check whether any of the compared objects is null.
        If x Is Nothing OrElse y Is Nothing Then Return False

        ' Check whether the products' properties are equal.
        Return (x.Code = y.Code) AndAlso (x.Name = y.Name)
    End Function

    Public Function GetHashCode1(
        ByVal product As Product
        ) As Integer Implements IEqualityComparer(Of Product).GetHashCode

        ' Check whether the object is null.
        If product Is Nothing Then Return 0

        ' Get hash code for the Name field if it is not null.
        Dim hashProductName = 
            If(product.Name Is Nothing, 0, product.Name.GetHashCode())

        ' Get hash code for the Code field.
        Dim hashProductCode = product.Code.GetHashCode()

        ' Calculate the hash code for the product.
        Return hashProductName Xor hashProductCode ' here.....................
    End Function
End Class