如何使用相同的代码从 DataRow 或 DataReader 中读取数据？

Question

目前，我使用的 SqlDataReader 加载了一个简单的数据库“选择”查询。每行代表一个域对象，因此我像这样膨胀每个对象：

Dim loadedItems As New List(Of Item)
Dim dr As SqlDataReader = GetItemsDataReader()
While dr.Read()
  Dim item As Item = GetItemFromData(dr)
  loadedItems.Add(item)
End While

我编写的 GetItemFromData 方法看起来像这样：

Private Function GetItemFromData(dr As SqlDataReader) As Item
  Dim loadedItem As New Item()
  loadedItem.ID = dr("ID")
  loadedItem.Name = dr("Name")
  'etc., etc.'
  Return loadedItem
End Function

在某些情况下，我必须从 DataRow 读取数据> 而不是 SqlDataReader。但代码是完全相同的！当我查看 GetItemFromData 方法时，我想在 dr 参数中接受更通用的对象类型，以便我可以处理 DataReader与 DataRow 相同，因为如果我编写了一个要使用 DataRow 的代码，我将在该方法中编写完全相同的代码。有办法做到这一点吗？

Answer 1

我能想到的唯一方法是包装一些类并实现一个接口 - 类似于：

Interface IIndexer
    Default ReadOnly Property Item(ByVal index As String)
End Interface

Class DataReaderWrapper
    Implements IIndexer

    Private ReadOnly _reader As IDataReader

    Public Sub New(reader As IDataReader)
        _reader = reader
    End Sub

    Public ReadOnly Property Item(index As String) As Object Implements IIndexer.Item
        Get
            Return _reader(index)
        End Get
    End Property
End Class

Class DataRowWrapper
    Implements IIndexer

    Private ReadOnly _row As DataRow

    Public Sub New(row As DataRow)
        _row = row
    End Sub

    Public ReadOnly Property Item(index As String) As Object Implements IIndexer.Item
        Get
            Return _row(index)
        End Get
    End Property
End Class

然后，您必须在将行或读取器传递给您的方法之前包装您的行或读取器：

Private Function GetItemFromData(indexer As IIndexer) As Item
    Dim loadedItem As New Item()
    loadedItem.ID = indexer("ID")
    loadedItem.Name = indexer("Name")
    'etc., etc.'
    Return loadedItem
End Function

Dim i As Item = GetItemFromData(New DataRowWrapper(dr))

Answer 2

如何使用 DataTable 代替：

Dim DataTable table AS new DataTable()
table.Load(GetItemsDataReader())
foreach (DataRow row in table.Rows) {
   Dim item As Item = GetItemFromData(row)
   loadedItems.Add(item)
}

更改 GetItemFromData() 方法以采用 DataRow 而不是 DataReader（对于 VB.NET/ C# 混合伪代码）。