偏移和结束功能

Question

我正在尝试将数据从 Q3 表 1 粘贴到 Q3 表 2。每条数据应粘贴在 Q3 表 2 上最后一条数据下方的一行（从单元格 A4 开始）。不幸的是，该行

Worksheets("Q3 Sheet 2").Range("A3").End(xlUp).Offset(1, 0) = .Offset(iRow, 0) 

不这样做。相反，它将所有数据粘贴到 A4 中，并且它们继续相互覆盖，因此，当从 A4 一直到 A14 应该有多个条目时，A4 中只有一个条目。请帮忙。谢谢！

  With Worksheets("Q3 Sheet 1").Range("A3")
        'Count total number of entries
        nCustomers = Range(.Offset(1, 0), .Offset(1, 0).End(xlDown)).Rows.Count
        'Loop through all entries looking for amounts owed > 1000
        For iRow = 1 To nCustomers
            AmountOwed = .Offset(iRow, 1) - .Offset(iRow, 2)
            'If amount owed > 1000 then transfer customer ID and amount owing to Q3 Sheet 2
            If AmountOwed > 1000 Then
                Worksheets("Q3 Sheet 2").Range("A3").End(xlUp).Offset(1, 0) = .Offset(iRow, 0)

            End If
        Next iRow
    End With

Answer 1

只需要两个小改动。

Worksheets("Q3 Sheet 2").Range("A3").End(xlUp).Offset(1, 0) = .Offset(iRow, 0)

应该读

Worksheets("Q3 Sheet 2").Range("A2").End(xlDown).Offset(1, 0) = .Offset(iRow, 0)

Answer 2

我重写了代码以使用范围（而不是使用范围来获取行然后循环行号），对变量进行标注并关闭屏幕更新（以提高速度），而且在查找时向上查找比向下查找更稳健最后记录

如果拥有的数量超过 1000，此版本会将整行从 Q3 表 1 复制到 Q3 表 2。它可以削减到您想要的任何数量的单元格（我认为您可能想要两个单元格？ ）

[更新：进一步整理代码，添加了 ws2 变量，删除了 AmountOwned 和冗余的 nCustomers]

   Sub Update()
   Dim ws As Worksheet
    Dim ws2 As Worksheet
    Dim rng1 As Range
    Dim rng2 As Range
    Application.ScreenUpdating = False
    Set ws = Worksheets("Q3 Sheet 1")
    Set ws2 = Worksheets("Q3 Sheet 2")
    Set rng1 = ws.Range(ws.[a4], ws.Cells(Rows.Count, "A").End(xlUp))
    For Each rng2 In rng1
        'If amount owed > 1000 then transfer customer ID and amount owing to Q3 Sheet 2
        If rng2.Offset(0, 1) - rng2.Offset(0, 2) > 1000 Then rng2.EntireRow.Copy ws2.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0)
    Next
    Application.ScreenUpdating = True        
    End Sub

Answer 3

将此行更改为

Worksheets("Q3 Sheet 2").Range("A3").End(xlDown).Offset(1, 0) = .Offset(iRow, 0) 

[] 的

Answer 4

Worksheets("Q3 Sheet 2").cells(rows.count,1).End(xlUp).Offset(1, 0) = .Offset(iRow, 0)

假设 A 列中工作表下方没有数据