泛型和 Marshal/UnMarshal。我在这里缺少什么？第 #2 部分:-)

Question

跟进我之前的问题： 泛型和 Marshal / UnMarshal。我在这里缺少什么？

在“第 1 部分”（上面的链接）中，TOndrej 提供了一个很好的解决方案 - 但在 XE2 上失败了。 在这里我提供了更正的来源来纠正这个问题。

我觉得有必要进一步扩展这个问题。 所以我想听听大家如何做到这一点：

首先 - 要让源代码在 XE2 和 XE2 更新 1 上运行，请进行这些更改：

Marshal.RegisterConverter(TTestObject,
  function (Data: TObject): String // <-- String here
  begin
    Result := T(Data).Marshal.ToString; // <-- ToString here
  end
  );

为什么？ 我认为与 XE2 相关的唯一原因是有更多的 RTTI 信息可用。因此它将尝试封送返回的 TObject。 我走在正确的轨道上吗？请随意发表评论。

更重要 - 该示例未实现 UnMarshal 方法。 如果有人可以制作一个并将其发布在这里，我会很高兴:-)

我希望您仍然对这个主题感兴趣。

亲切的问候 比亚内

Answer 1

除了这个问题的答案之外，我还在这里发布了您上一个问题的解决方法：泛型和 Marshal / UnMarshal。我在这里缺少什么？

由于某种原因，使用 TJsonobject 的非默认构造函数会导致 XE2 中出现问题 - 使用默认构造函数“修复”了该问题。

首先，您需要将 TTestobject 移动到其自己的单元 - 否则，RTTI 在尝试解组时将无法找到/创建您的对象。

    unit uTestObject;

    interface

    uses
      SysUtils, Classes, Contnrs, Generics.Defaults, Generics.Collections, DbxJson, DbxJsonReflect;

    type
      {$RTTI EXPLICIT METHODS([]) PROPERTIES([vcPublished]) FIELDS([vcPrivate])}
      TTestObject=class(TObject)
      private
        aList:TStringList;
      public
        constructor Create; overload;
        constructor Create(list: array of string); overload;
        constructor Create(list:TStringList); overload;
        destructor Destroy; override;
        function Marshal:TJSonObject;
        class function Unmarshal(value: TJSONObject): TTestObject;
      published
        property List: TStringList read aList write aList;
      end;

    implementation

    { TTestObject }

    constructor TTestObject.Create;

    begin
      inherited Create;
      aList:=TStringList.Create;
    end;

    constructor TTestObject.Create(list: array of string);

    var
      I:Integer;

    begin
      Create;
      for I:=low(list) to high(list) do
        begin
          aList.Add(list[I]);
        end;
    end;

    constructor TTestObject.Create(list:TStringList);

    begin
      Create;
      aList.Assign(list);
    end;

    destructor TTestObject.Destroy;

    begin
      aList.Free;
      inherited;
    end;

    function TTestObject.Marshal:TJSonObject;

    var
      Mar:TJSONMarshal;

    begin
      Mar:=TJSONMarshal.Create();
      try
        Mar.RegisterConverter(TStringList,
          function(Data:TObject):TListOfStrings

          var
            I, Count:Integer;
          begin
            Count:=TStringList(Data).Count;
            SetLength(Result, Count);
            for I:=0 to Count-1 do
              Result[I]:=TStringList(Data)[I];
          end);
        Result:=Mar.Marshal(Self) as TJSonObject;
      finally
        Mar.Free;
      end;
    end;

    class function TTestObject.Unmarshal(value: TJSONObject): TTestObject;

    var
      Mar: TJSONUnMarshal;
      L: TStringList;

    begin
      Mar := TJSONUnMarshal.Create();
      try
        Mar.RegisterReverter(TStringList,
          function(Data: TListOfStrings): TObject

          var
            I, Count: Integer;
          begin
            Count := Length(Data);
            Result:=TStringList.Create;
            for I := 0 to Count - 1 do
              TStringList(Result).Add(string(Data[I]));
          end
        );
        //UnMarshal will attempt to create a TTestObject from the TJSONObject data
        //using RTTI lookup - for that to function, the type MUST be defined in a unit
        Result:=Mar.UnMarshal(Value) as TTestObject;
      finally
        Mar.Free;
      end;
    end;

    end.

另请注意，构造函数已被重载 - 这使您可以看到代码可以正常运行，而无需在创建过程中预先填充对象中的数据。

这是泛型类列表对象的实现

    unit uTestObjectList;

    interface

    uses
      SysUtils, Classes, Contnrs, Generics.Defaults, Generics.Collections,
      DbxJson, DbxJsonReflect, uTestObject;

    type
      {$RTTI EXPLICIT METHODS([]) PROPERTIES([]) FIELDS([])}
      TTestObjectList<T:TTestObject,constructor> = class(TObjectList<T>)
      public
        function Marshal: TJSonObject;
        constructor Create;
        class function Unmarshal(value: TJSONObject): TTestObjectList<T>; static;
      end;

    //Note: this MUST be present and initialized/finalized so that
    //delphi will keep the RTTI information for the generic class available
    //also, it MUST be "project global" - not "module global"
    var
      X:TTestObjectList<TTestObject>;

    implementation

    { TTestObjectList<T> }
    constructor TTestObjectList<T>.Create;
    begin
      inherited Create;
      //removed the add for test data - it corrupts unmarshaling because the data is already present at creation
    end;

    function TTestObjectList<T>.Marshal: TJSonObject;
    var
      Marshal: TJsonMarshal;
    begin
      Marshal := TJSONMarshal.Create;
      try
        Marshal.RegisterConverter(TTestObjectList<T>,
          function(Data: TObject): TListOfObjects
          var
            I: integer;

          begin
            SetLength(Result,TTestObjectlist<T>(Data).Count);
            for I:=0 to TTestObjectlist<T>(Data).Count-1 do
              Result[I]:=TTestObjectlist<T>(Data)[I];
          end
        );
        Result := Marshal.Marshal(Self) as TJSONObject;
      finally
        Marshal.Free;
      end;
    end;

    class function TTestObjectList<T>.Unmarshal(value: TJSONObject): TTestObjectList<T>;

    var
      Mar: TJSONUnMarshal;
      L: TStringList;

    begin
      Mar := TJSONUnMarshal.Create();
      try
        Mar.RegisterReverter(TTestObjectList<T>,
          function(Data: TListOfObjects): TObject
          var
            I, Count: Integer;
          begin
            Count := Length(Data);
            Result:=TTestObjectList<T>.Create;
            for I := 0 to Count - 1 do
              TTestObjectList<T>(Result).Unmarshal(TJSONObject(Data[I]));
          end
        );
        //UnMarshal will attempt to create a TTestObjectList<TTestObject> from the TJSONObject data
        //using RTTI lookup - for that to function, the type MUST be defined in a unit,
        //and, because it is generic, there must be a GLOBAL VARIABLE instantiated
        //so that Delphi keeps the RTTI information avaialble
        Result:=Mar.UnMarshal(Value) as TTestObjectList<T>;
      finally
        Mar.Free;
      end;
    end;


    initialization
      //force delphi RTTI into maintaining the Generic class information in memory
      x:=TTestObjectList<TTestObject>.Create;

    finalization
      X.Free;

    end.

有几件事需要注意：
如果在运行时创建通用类，则不会保留 RTTI 信息，除非内存中有对该类的全局可访问对象引用。请参阅此处： Delphi：RTTI 和 TObjectList

因此，上述单元创建了这样一个变量并按照链接文章中的讨论将其实例化。

主要过程已更新，显示了两个对象的数据编组和解组：

    procedure Main;
    var
      aTestobj,
      bTestObj,
      cTestObj : TTestObject;
      aList,
      bList : TTestObjectList<TTestObject>;
      aJsonObject,
      bJsonObject,
      cJsonObject : TJsonObject;

      s: string;

    begin
      aTestObj := TTestObject.Create(['one','two','three','four']);
      aJsonObject := aTestObj.Marshal;
      s:=aJsonObject.ToString;
      Writeln(s);

      bJsonObject:=TJsonObject.Create;
      bJsonObject.Parse(BytesOf(s),0,length(s));

      bTestObj:=TTestObject.Unmarshal(bJsonObject) as TTestObject;
      writeln(bTestObj.List.Text);

      writeln('TTestObject marshaling complete.');
      readln;

      aList := TTestObjectList<TTestObject>.Create;
      aList.Add(TTestObject.Create(['one','two']));
      aList.Add(TTestObject.Create(['three']));
      aJsonObject := aList.Marshal;
      s:=aJsonObject.ToString;
      Writeln(s);

      cJSonObject:=TJsonObject.Create;
      cJSonObject.Parse(BytesOf(s),0,length(s));
      bList:=TTestObjectList<TTestObject>.Unmarshal(cJSonObject) as TTestObjectList<TTestObject>;
      for cTestObj in bList do
        begin
          writeln(cTestObj.List.Text);
        end;

      writeln('TTestObjectList<TTestObject> marshaling complete.');
      Readln;
    end;

Answer 2

这是我自己的解决方案。

由于我非常喜欢多态性，所以我实际上也想要一个可以构建到对象层次结构中的解决方案。假设 TTestObject 和 TTestObjectList 是我们的 BASE 对象。从这里我们下降到 TMyObject 和 TMyObjectList。此外，我还对对象和列表进行了更改 - 为 Marshaller/UnMarshaller 添加了属性，

TMyObject = class(TTestObject) and TMyObjectList<T:TMyObject> = class(TTestObjectList)

现在我们引入了一些新问题。 IE。如何处理层次结构中各行之间不同类型的编组，以及如何将 TJsonMarshal 和 TJsonUnMarshal 作为 TTestObject 和 List 上的属性进行处理。

这可以通过在 TTestObject 级别引入两种新方法来克服。两个类函数称为 RegisterConverters 和 RegisterReverters。然后我们着手将 TTestObjectList 的编组函数更改为更简单的编组。

对象和列表的两个类函数和属性。

class procedure RegisterConverters(aClass: TClass; aMar: TJSONMarshal); virtual;
class procedure RegisterReverters(aClass: TClass; aUnMar: TJSONUnMarshal); virtual;

property Mar: TJSONMarshal read FMar write SetMar;
property UnMar: TJSONUnMarshal read FUnMar write SetUnMar;

List 的 Marshal 函数现在可以像这样完成：

function TObjectList<T>.Marshal: TJSONObject;
begin
  if FMar = nil then
    FMar := TJSONMarshal.Create(); // thx. to SilverKnight
  try
    RegisterConverters; // Virtual class method !!!!
    try
      Result := FMar.Marshal(Self) as TJSONObject;
    except
      on e: Exception do
        raise Exception.Create('Marshal Error : ' + e.Message);
    end;
  finally
    ClearMarshal; // FreeAndNil FMar and FUnMar if assigned.
  end;
end;

当然，我们仍然可以为 TTestObject 有一个编组器 - 但 TTestObjectList 的 Marshal 函数不会使用它。这样，当调用 TTestObjectList（或后代）的 Marshal 时，只会创建一个 Marshaller。这样，我们最终只会编组我们在向后执行所有操作时重新创建结构所需的信息 - UnMarshalling :-)

现在这实际上有效 - 但我想知道是否有人对此有任何评论？

让我们向 TMyTestObject 添加属性“TimeOfCreation”：
属性 TimeOfCreation ：TDateTime 读取 FTimeOfCreation 写入 FTimeOfCreation；

并在构造函数中设置属性。

FTimeofCreation := now;

然后我们需要一个转换器，因此我们重写 TTestObject 的虚拟 RegisterConverters。

class procedure TMyTestObject.RegisterConverters(aClass: TClass; aMar: TJSONMarshal);
begin
  inherited;  // instanciate marshaller and register TTestObject converters
  aMar.RegisterConverter(aClass, 'FTimeOfCreation',
    function(Data: TObject; Field: String): string
    var
      ctx: TRttiContext;
      date: TDateTime;
    begin
      date := ctx.GetType(Data.ClassType).GetField(Field).GetValue(Data).AsType<TDateTime>;
      Result := FormatDateTime('yyyy-mm-dd hh:nn:ss', date);
    end);
end;

我最终得到了非常简单的源代码，例如使用 TTestObject ie。

aList := TMyTestObjectList<TMyTestObject>.Create;
      aList.Add(TMyTestObject.Create(['one','two']));
      aList.Add(TMyTestObject.Create(['three']));
      s := (aList.Marshal).ToString;
      Writeln(s);

现在我已经成功地进行了多态性编组:-) 顺便说一句，

这也适用于 UnMarshalling。我正在重建我的 FireBird ORM 来为我的所有对象生成源代码，就像这样。

当前的旧版本可以在这里找到：
http://code.google.com/p/objectgenerator/
请记住，它仅适用于 FireBird :-)