是否可以只通过一次就对列表进行快速排序？

Question

我正在学习haskell，我看到的函数定义是：

quickSort (x : xs) = (quickSort less) ++ (x : equal) ++ (quickSort more)
                 where less = filter (< x) xs
                       equal = filter (== x) xs
                       more = filter (> x) xs

是否可以只用列表的一次遍历而不是3次来编写它？

Answer 1

你的意思是这样的吗？

quicksort [] = []
quicksort (x:xs) = quicksort less ++ (x : equal) ++ quicksort more
  where (less, equal, more) = partition3 x xs

partition3 _ [] = ([], [], [])
partition3 x (y:ys) =
  case compare y x of
    LT -> (y:less, equal, more)
    EQ -> (less, y:equal, more)
    GT -> (less, equal, y:more)
  where (less, equal, more) = partition3 x ys

请注意，这并不是真正的快速排序，因为真正的快速排序是就地的。

Answer 2

它似乎没有改善任何事情，但：

qs (x:xs) = let (a,b) = partition (< x) xs in (qs a) ++ [x] ++ (qs b)

Answer 3

尽管晚了，但这里的版本应该不会泄漏那么多空间（并且似乎比这里的其他三路版本运行速度大约快两倍）：

qsort3 xs = go xs [] 
  where
    go     (x:xs) zs       = part x xs zs [] [] []
    go     []     zs       = zs
    part x []     zs a b c = go a ((x : b) ++ go c zs)
    part x (y:ys) zs a b c =
        case compare y x of
                  LT -> part x ys zs (y:a) b c
                  EQ -> part x ys zs a (y:b) c
                  GT -> part x ys zs a b (y:c)

这解决了使用元组时可能出现的问题，其中< code>let (a,b) = ... 实际上翻译为 let t= ...; a=fst t； b=snd t 这会导致即使在 a 被消耗和处理之后，它仍然保持活动状态，作为元组 t 的一部分，以便从中读取 b - 尽管当然完全没有必要。这被称为“Wadler 对空间泄漏”问题。或者也许 GHC（带有 -O2）比这更聪明。 :)

另外，这显然使用了差异列表方法（谢谢，hammar），这也使其更加高效（大约比使用元组的版本快两倍）。我认为 part 使用累加器参数，因为它以相反的顺序构建它们。