perl：我可以等15分钟，然后如果没有按下某个键，就做点什么吗？

Question

这是我的第一个 Perl 程序：

我想确保如果我离开我的机器一段时间，那么这个脚本会通过 ssh 连接到我们的主服务器并杀死那里的所有进程。 （当我去吃午饭时，我总是忘记杀死它们，它们占用了大量的CPU和内存）。

我已经走到这一步了，屏幕保护程序激活 15 分钟后，杀戮就开始了。

#!/usr/bin/perl

my $cmd = "dbus-monitor --session \"type='signal',interface='org.gnome.ScreenSaver',member='ActiveChanged'\"";

open (IN, "$cmd |");

while (<IN>) {
    if (m/^\s+boolean true/) {
        print "*** Screensaver is active ***\n";
        print "*** Sleeping before megadeath....\n";
        sleep(15*60);
        print "*** killing all jla processes on anvil...\n";
        $result = `ssh anvil pkill -u jla`;
        print "*** should all be dead\n";
        print $result;

    } elsif (m/^\s+boolean false/) {
        print "*** Screensaver is no longer active ***\n";
    }
}

但我想要的是等待 15 分钟，同时监视键盘。如果说，按下“N”键（在脚本运行的终端中），那么我想中止杀戮并返回监视屏幕保护程序。如果我在喝咖啡时屏幕保护程序打开，这将为我提供一条逃生路线。

某种邦德风格的倒计时也不错。

实际上，更好的方法是注意屏幕保护程序何时解锁，如果是这样，则停止倒计时，返回监控模式。然后我什至不用担心记得按 N。

Answer 1

如果你的 Perl 有线程支持，你可以这样做：

#!/usr/bin/perl

use warnings; use strict;

use threads;
use threads::shared;
use Term::ReadKey;

my $DONT_TERMINATE :shared;
my $TIMEOUT = 5;

threads->new( sub { wait_for_keypress('n', $TIMEOUT) })->detach;
threads->new( sub { countdown($TIMEOUT) })->join;

sub countdown {
    my ($timeout) = @_;

    while ( 1 ) {
        my $elapsed = time - $^T;
        last if $elapsed >= $timeout;
        return if $DONT_TERMINATE;
        print $timeout - $elapsed, "\n";
        sleep 1;
    }

    print "Killing some processes\n";
}

sub wait_for_keypress {
    my ($key, $timeout) = @_;
    my $input = ReadKey( $timeout );

    $DONT_TERMINATE = (defined($input) and ($input eq $key));

    return;
}

如果你没有线程支持，你可以使用 科罗。

注意：我删除了我的 Coro 示例，因为它无法正常工作。如果我弄清楚了，我会再次发布。

Answer 2

我会使用 select< /a> （通过 IO::Select），其中让你检查如果文件句柄有准备好的数据。但是，您不能将“缓冲”IO 运算符（例如 <> 与 select 一起使用）使用，因此这比您可能希望的更复杂（您必须使用 sysread 并维护您自己的缓冲区）。以下是如何观看屏幕保护程序活动，并在屏幕保护程序已打开 15 分钟后执行某些操作。

use IO::Select;
my $s = IO::Select->new();
# ... Start dbus-monitor as above ...
$s->add(\*IN);

my $buf = '';
my $started = 0;
my $waitfor = 15*60;
while ( 1 ) {
    # Read from all ready filehandles (timeout if none ready after 1 sec)
    foreach my $fh ( @ready = $s->can_read(1) ) {
        sysread($fh, $buf, 128, length($buf));
    }
    # Handle each complete line of input
    while ( $buf =~ s/^(.+)\n// ) {
        my $line = $1
        # ... Do something ...
        if ( $line =~ m/^\s+boolean (true|false)/ ) {
            if ( $1 eq 'true' ) { $started = time; print "Starting timer\n" }
            else { $started = 0; print "Canceled timer\n" }
        }
    }
    next unless $started;

    # Screensaver is on, how long has it been running?
    my $timeleft = $started+$waitfor-time;
    if ( $timeleft <= 0 ) {
        print "The screensaver has been on for at least 15 minutes\n";
        # ... Do something ...
        $started = 0; # Don't do this again until the screensaver is restarted
    }
    else {
        # You can print out an updated countdown
        print "$timeleft seconds left\n";
    }
}

我根本没有测试过这个，但这可能足以让你让它工作。

_{PS 它不适用于 Windows，其中 select 仅适用于套接字。}

Answer 3

Sinan 和 nandhp 的解决方案将适用于这项任务。 threads 和 select 是 Perl 程序员武器库中的强大工具，但我不愿意将它们推荐给某人的“第一个 Perl（原文如此）程序”。所以我会建议另一种方法。

为了过度简化这个问题的描述，我们想要在发生其他事情（屏幕保护程序已激活 15 分钟）时执行某些操作（触发命令来终止远程服务器上的进程）。

 use strict;
 use warnings;

 initialize_program();
 until (something_happens()) {
     sleep 60;
 }
 do_something();
 exit;

do_something 部分很简单：

 sub do_something {
    print "*** killing all jla processes on anvil...\n";
    $result = `ssh anvil pkill -u jla`;
    print "*** should all be dead\n";
    print $result;
 }

对于程序的 something_happens 部分，我建议将 dbus-monitor 输出发送到一个文件中后台进程，并在您想了解屏幕保护程序的状态时从文件中读取。 dbus-monitor 程序生成输出的速度相当慢，并且从 Perl 文件句柄读取往往会阻塞（除非您了解并使用 select）。

我将稍微调整一下 dbus-monitor 命令。每次屏幕保护程序的状态发生变化时，此命令都会打印出一个时间戳：

 my $command = q[dbus-monitor --session "type='signal',interface='org.gnome.ScreenSaver',member='ActiveChanged'" | perl -ne 'print time," $_" if /boolean/'];

我们将通过执行以下命令来启动我们的程序：

sub initialize_program {
    # broken into multiple lines for readability
    my $command = q[dbus-monitor --session ]
            . q["type='signal',interface='org.gnome.ScreenSaver',member='ActiveChanged'"]
            . q[ | perl -ne 'print time," $_" if /boolean/'];

    system("$command > /tmp/screensavermonitor &");
}

现在，为了查看屏幕保护程序是否处于活动状态以及活动时间，我们解析 /tmp/screensavermonitor每隔一段时间。

sub something_happens {
    open (my $fh, '<', '/tmp/screensavermonitor') or return do { warn $!;0 };
    my @output = <$fh>;
    close $fh;

    # we only care about the last output
    my $state = pop @output;
    if (!defined $state) {
         # maybe there's no output yet
         return 0;
    }

    if ($state =~ /false/) {
        # screensaver is not active
        return 0;   # event hasn't happened yet
    }

    if ($state =~ /true/) {
        # screensaver is active -- but for how long?
        # start time (in seconds since the epoch) is included in output
        my ($screensaver_start_time) = ($state =~ /(\d+)/);
        if (time - $screensaver_start_time >= 15 * 60) {
            return 1;
        } else {
            return 0;
        }
    }
    return 0;
}

Answer 4

正如 mob 所说，线程和 select 使这有点复杂化。因此，这是 Term::ReadKey 的一些简单易用的功能，它可以让您执行以下操作：您首先要求的是：等待按下某个键，但如果 15 分钟内没有按下任何键，则超时。

#!/usr/bin/env perl

use strict;
use warnings;

use Term::ReadKey;
my $cmd = "dbus-monitor --session \"type='signal', interface='org.gnome.ScreenSaver',member='ActiveChanged'\"";

open(IN, "$cmd |");

ReadMode 'cbreak';    # return keypress immediately without waiting for "Enter"

while (<IN>) {
  if (m/^\s+boolean true/) {
    print "*** Screensaver is active ***\n";
    print "*** Sleeping before megadeath....\n";

    my $key = ReadKey 900;    # timeout after 900 seconds = 15 minutes
    if (defined $key) {
      print "*** A key was pressed; megadeath averted\n";
    } else {
      print "*** killing all jla processes on anvil...\n";
      my $result = `ssh anvil pkill -u jla`;
      print "*** should all be dead\n";
      print $result;
    }
  } elsif (m/^\s+boolean false/) {
    print "*** Screensaver is no longer active ***\n";
  }
}

ReadMode 'restore';    # back to normal input mode

（代码在语法上是正确的，但尚未运行，因此未经过充分测试。除了“cbreak”之外，您可能还需要设置“noecho”ReadMode，以防止按下导致禁用超级死亡的按键出现在屏幕上。）