键盘事件 as3 不起作用

Question

这件事让我敲了两个小时才弄清楚。
我决定将其发布在这里，以帮助其他人不要拔毛:)。

本质上，错误是我没有从 Flash 构建器环境中接收键盘事件（在 adobe flash cs5 中也可以看到相同的错误/问题）。我设置了stage.focus = stage，没有帮助。我添加了其他事件侦听器（mouse_down、frame_enter），效果很好，我添加了 MovieClip 子项并侦听这些子项上的事件，但仍然是同样的问题。

package
{
  public class Test extends Sprite 
  {

    public function Test() 
    {
        this.addEventListener(Event.ADDED_TO_STAGE,init);
    }

    public function init(stage:Stage):void 
    {
        this.removeEventListener(Event.ADDED_TO_STAGE,init);
        stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
        stage.addEventListener(KeyboardEvent.KEY_UP, keyReleased);
    }


    private function keyPressed(e:KeyboardEvent):void 
    {
        trace("keyPressed");
    }

    private function keyReleased(e:KeyboardEvent):void 
    {
        trace("keyReleased");
    }
  }
}

Answer 1

public function init(stage:Stage):void 

ADDED_TO_STAGE is a `listener Event` not a stage instance. 

因此，请使用 event:Event 而不是 stage:Stage。

你需要导入所需的类。

Answer 2

标记发生更改的行。顺便说一句，您的代码无法编译，请检查错误日志。

package  {

import flash.display.Sprite; /// changed line
import flash.events.Event; /// changed line
import flash.events.KeyboardEvent; /// changed line


public class Test extends Sprite 
{

public function Test() 
{
    this.addEventListener(Event.ADDED_TO_STAGE,init);
    /* i like it this way
    stage ? init(null) : addEventListener(Event.ADDED_TO_STAGE,init);
    */

}

public function init(e:Event):void  /// changed line
{
    this.removeEventListener(Event.ADDED_TO_STAGE,init);
    stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
    stage.addEventListener(KeyboardEvent.KEY_UP, keyReleased);
}


private function keyPressed(e:KeyboardEvent):void 
{
    trace("keyPressed");
}

private function keyReleased(e:KeyboardEvent):void 
{
    trace("keyReleased");
}
}

}

Answer 3

使用键盘命令需要监听键盘事件。此过程与侦听 AS3 中任何其他事件的过程相同。您需要使用addEventListener()方法来注册KeyboardEvent。然而，与其他对象不同的是，由于键盘不需要附加到项目中的任何特定对象，因此键盘事件通常注册到舞台。在下面的代码中，舞台对象注册每次按下键盘键时触发的键盘事件。

与 AS2 不同，AS3 键盘事件不是全局的。它们被发送到舞台，并通过显示列表冒泡到具有焦点的任何显示对象。

package
{
import flash.display.*;
import flash.events.*;

  public class Test extends Sprite 
  {
   public function Test() 
   {
     init();
   }

   public function init():void 
   {
      stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
      stage.addEventListener(KeyboardEvent.KEY_UP, keyReleased);
   }


   private function keyPressed(e:KeyboardEvent):void 
   {
      trace("keyPressed");
   }

   private function keyReleased(e:KeyboardEvent):void 
   {
    trace("keyReleased");
   }
  }
}