Haskell http 响应结果不可读

Question

import Network.URI
import Network.HTTP
import Network.Browser

get :: URI -> IO String
get uri = do
  let req = Request uri GET [] ""
  resp <- browse $ do
    setAllowRedirects True -- handle HTTP redirects
    request req
  return $ rspBody $ snd resp

main = do
  case parseURI "http://cn.bing.com/search?q=hello" of
    Nothing -> putStrLn "Invalid search"
    Just uri -> do
        body <- get uri
        writeFile "output.txt" body

这是 haskell 输出和curl 输出之间的差异

Answer 1

此处使用 String 作为中间数据类型可能不是一个好主意，因为它会在读取 HTTP 响应和写入文件时导致字符转换。如果这些转换不一致，则可能会导致损坏，就像它们在这里一样。

由于您只想直接复制字节，因此最好使用ByteString。我选择在这里使用惰性ByteString，这样它就不必一次全部加载到内存中，而是可以惰性地流式传输到文件中，就像String< /代码>。

import Network.URI
import Network.HTTP
import Network.Browser
import qualified Data.ByteString.Lazy as L

get :: URI -> IO L.ByteString
get uri = do
  let req = Request uri GET [] L.empty
  resp <- browse $ do
    setAllowRedirects True -- handle HTTP redirects
    request req
  return $ rspBody $ snd resp

main = do
  case parseURI "http://cn.bing.com/search?q=hello" of
    Nothing -> putStrLn "Invalid search"
    Just uri -> do
        body <- get uri
        L.writeFile "output.txt" body

幸运的是，Network.Browser 中的函数已重载，因此对惰性字节串的更改只需将请求正文更改为 L.empty，替换 writeFile > 与L.writeFile，以及更改函数的类型签名。