Glsl mod 与 Hlsl fmod

Question

我已经在 HLSL 中实现了 这个问题中描述的螺旋 GLSL 着色器，但结果并不相同。我认为这是因为我将 GLSL 中的 mod 函数翻译为 HLSL 中的 fmod 。我怀疑只有当 fmod 函数的输入中有负数时才会出现此问题。

我尝试将对 mod 的调用替换为对我所做的函数的调用，该函数执行 GLSL 文档 它的工作原理：

mod 返回 x 对 y 取模的值。计算公式为x - y * Floor(x/y)。

我使用的代替 fmod 的工作代码是：

float mod(float x, float y)
{
  return x - y * floor(x/y)
}

与 GLSL mod 相比，MSDN 说 HLSL fmod 函数执行以下操作：

浮点余数的计算方式为x = i * y + f，其中i是一个整数，f有与x符号相同，且f的绝对值小于y的绝对值。

我使用了HLSL 到 GLSL 转换器，并且 fmod 函数是翻译为mod。但是，我不知道是否可以假设 mod 转换为 fmod。

问题

1. GLSL mod 和 HLSLfmod 之间有什么区别？
2. 如何将 MSDN 对 fmod 的神秘描述转换为伪代码实现？

GLSL 着色器

uniform float time;
uniform vec2 resolution;
uniform vec2 aspect;

void main( void ) {
  vec2 position = -aspect.xy + 2.0 * gl_FragCoord.xy / resolution.xy * aspect.xy;
  float angle = 0.0 ;
  float radius = length(position) ;
  if (position.x != 0.0 && position.y != 0.0){
    angle = degrees(atan(position.y,position.x)) ;
  }
  float amod = mod(angle+30.0*time-120.0*log(radius), 30.0) ;
  if (amod<15.0){
    gl_FragColor = vec4( 0.0, 0.0, 0.0, 1.0 );
  } else{
    gl_FragColor = vec4( 1.0, 1.0, 1.0, 1.0 );                    
  }
}

HLSL 着色器

struct Psl_VertexShaderInput
{
    float3 pos : POSITION;
};

struct Psl_VertexShaderOutput
{
    float4 pos : POSITION;

};

struct Psl_PixelShaderOutput
{
    float4 Output0 : COLOR0;
};

float3 psl_positionOffset;
float2 psl_dimension;

Psl_VertexShaderOutput Psl_VertexShaderFunction(Psl_VertexShaderInput psl_input)
{
    Psl_VertexShaderOutput psl_output = (Psl_VertexShaderOutput)0;

    psl_output.pos = float4(psl_input.pos + psl_positionOffset, 1);


    return psl_output;
}

float time : TIME;
float2 resolution : DIMENSION;


Psl_PixelShaderOutput Psl_PixelShaderFunction(float2 pos : VPOS)
{
    Psl_PixelShaderOutput psl_output = (Psl_PixelShaderOutput)0;

    float2 aspect = float2(resolution.x / resolution.y, 1.0);
    float2 position = -aspect.xy + 2.0 * pos.xy / resolution.xy * aspect.xy;
    float angle = 0.0;
    float radius = length(position);
    if (position.x != 0.0 && position.y != 0.0)
    {
        angle = degrees(atan2(position.y, position.x));
    }
    float amod = fmod((angle + 30.0 * time - 120.0 * log(radius)), 30.0);
    if (amod < 15.0)
    {
        psl_output.Output0 = float4(0.0, 0.0, 0.0, 1.0);
        return psl_output;
    }

    else
    {
        psl_output.Output0 = float4(1.0, 1.0, 1.0, 1.0);
        return psl_output;
    }

}

technique Default
{
    pass P0
    {
        VertexShader = compile vs_3_0 Psl_VertexShaderFunction();
        PixelShader = compile ps_3_0 Psl_PixelShaderFunction();
    }
}

Answer 1

正如您所指出的，它们是不同的。 GLSL mod 始终具有与 y 相同的符号，而不是 x。否则它是相同的——一个值f，使得x = i*y + f，其中i是一个整数，而|f | < |y|。如果您尝试制作某种重复模式，GLSL mod 通常就是您想要的。

为了进行比较，HLSL fmod 相当于 x - y * trunc(x/y)。当x/y为正数时它们是相同的，当x/y为负数时它们不同。