已使用 Rhino.Mocks 正确分配模拟对象的断言属性

Question

在（Web）应用程序中，我实现了 MVP 模式来分离核心关注点。我的演示者使用 LINQ-to-NHibernate 直接查询数据库，或者有时当查询变得复杂时他们使用查询对象（但我离题了）。

我的演示者之一的一个简单示例如下（注意：VB.NET 不是我的偏好，但这是一个要求）：（

Public Class CampusListPresenter
    Inherits BasePresenter(Of ICampusListView)

    Public Sub New(ByVal view As ICampusListView)
        MyBase.New(view)
    End Sub

    Public Sub NeedDataSource()

        Using uow As ISession = _sessionManager.OpenSession()

            _view.DataSource = uow.Queryable(Of Campus)() _
            .Cacheable() _
            .AsEnumerable()

        End Using

    End Sub

End Class

简化的）基本演示者类如下：

Public MustInherit Class BasePresenter(Of TView)

    Protected _view As TView

    Protected _sessionManager As ISessionManager

    Public Sub New(ByVal view As TView)
        Guard.Against(view Is Nothing, "view cannot be null.")
        _view = view
    End Sub

    Public WriteOnly Property SessionManager As ISessionManager
        Set(ByVal value As ISessionManager)
            _sessionManager = value
        End Set
    End Property

End Class

我正在尝试对我的演示者进行单元测试（特别是 LINQ 查询）使用 NUnit 和 Rhino Mocks。在上述 CampusListPresenter 的单元测试用例中，我将模拟视图传递给演示者。本质上，我想对此模拟视图对象执行断言，以确认 Datasouce 属性已正确设置。然而，这始终为空。

我的单元测试的（简化的）示例如下（请理解，我对正确的单元测试相对较新）：

<TestFixture()> _
Public Class CampusListPresenterTests

    Dim _realSessionManager As ISessionManager

    <TestFixtureSetUp()> _
    Public Sub TestFixtureSetUp()
        _realSessionManager = DefaultSessionManager.Instance
    End Sub

    Dim _view As ICampusListView
    Dim _fakeSessionManager As ISessionManager

    <SetUp()> _
    Public Sub Setup()
        _view = MockRepository.GenerateMock(Of ICampusListView)()
        _fakeSessionManager = MockRepository.GenerateMock(Of ISessionManager)()
    End Sub

    <Test()> _
    Public Sub NeedDataSource_UsingRealSession_DataSourceIsAssigned()

        'Arrange
        Dim realSession As ISession = _realSessionManager.OpenSession()
        _fakeSessionManager.Expect(Function(sm) sm.OpenSession()).Return(realSession)

        'Act
        Dim presenter As New CampusListPresenter(_view)
        presenter.SessionManager = _fakeSessionManager
        presenter.NeedDataSource()

        'Assert
        _fakeSessionManager.VerifyAllExpectations()
        Assert.AreEqual(_view.DataSource, realSession.Queryable(Of Campus)())

    End Sub

End Class

我实际上将单元测试设置为使用内存中的 SQLite 数据库并在设置/拆卸方法中填充/销毁数据，但为了简单起见，上面的示例已将其全部省略。

基本上，在这个单元测试中，我从模拟的会话管理器（用于会话管理的类 - 想想 Castle.Facilities.NHibernateIntegration）返回一个真正的 NHibernate ISession，以便 LINQ-to-NHibernate 可以/将实际返回有效的可枚举结果。无论如何，在演示者实现中，我分配了视图数据源（在 NeedDataSource 内），但是当我对此属性进行断言时，分配的值始终为 null。

有人可以帮我吗？

亲切的问候， 瑞安.

Answer 1

模拟的 ICampusListView 无法保留分配的数据源对象。这里有两种可能的方法来解决这个问题。首先，您可以使用存根而不是模拟（有关模拟和存根之间差异的更多背​​景信息，请参阅 this post）：

_view = MockRepository.GenerateStub(Of ICampusListView)()

如果您确实想使用模拟而不是存根，请使用 Expect 和测试中 ICampusListView 对象上的 VerifyAllExpectations：

    'Arrange
    Dim realSession As ISession = _realSessionManager.OpenSession()
    _fakeSessionManager.Expect(Function(sm) sm.OpenSession()).Return(realSession)
    _view.Expect(Function(v) v.SetDataSource(Arg(Of DataSource).Is.Anything))

    'Act
    Dim presenter As New CampusListPresenter(_view)
    presenter.SessionManager = _fakeSessionManager
    presenter.NeedDataSource()

    'Assert
    _fakeSessionManager.VerifyAllExpectations()
    _view.VerifyAllExpectations()
    Assert.AreEqual(_view.DataSource, realSession.Queryable(Of Campus)())