需要通过 XSLT 获取不同的元素

Question

我在名为 Query 的元素下有一个可能重复的表元素列表，我需要获取不同的表元素（不是它的值，而是标签/元素名称本身。

/ShopArea/Connection/Query/* 列表表名称包括重复项。

下面是 XML

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="ShopArea.xslt"?>
<ShopArea>
<Connection name="Connection1">
    <Report date="25-09-2011">

        <Query id="1">
            <TABLE1>1.1</TABLE1>
            <TABLE2>1.2</TABLE2>
            <TABLE3>1.3</TABLE3>
        </Query>
        <Query id="2">
            <TABLE21>2.1</TABLE21>
            <TABLE22>2.2</TABLE22>
            <TABLE23>2.3</TABLE23>
        </Query>
    </Report>

    <Report date="26-09-2011">
        <Query id="1">
            <TABLE1>26 1.1</TABLE1>
            <TABLE2>26 1.2</TABLE2>
            <TABLE3>26 1.3</TABLE3>
        </Query>
        <Query id="2">
            <TABLE21>26 2.1</TABLE21>
            <TABLE22>26 2.2</TABLE22>
            <TABLE23>26 2.3</TABLE23>
        </Query>
    </Report>
</Connection>
</ShopArea>

我引用了 如何在 XSLT 中选择唯一节点但我不是能够做对。

Answer 1

我。 XSLT 1.0。此转换使用简单的 Muenchian 分组：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kChildByName" match="Query/*"
  use="name()"/>

 <xsl:template match=
  "Query/*
       [generate-id()
       =
        generate-id(key('kChildByName', name())[1])
       ]">
     <xsl:value-of select="name()"/>
     <xsl:text>
</xsl:text>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

当应用于提供的 XML 文档：

<ShopArea>
    <Connection name="Connection1">
        <Report date="25-09-2011">
            <Query id="1">
                <TABLE1>1.1</TABLE1>
                <TABLE2>1.2</TABLE2>
                <TABLE3>1.3</TABLE3>
            </Query>
            <Query id="2">
                <TABLE21>2.1</TABLE21>
                <TABLE22>2.2</TABLE22>
                <TABLE23>2.3</TABLE23>
            </Query>
        </Report>
        <Report date="26-09-2011">
            <Query id="1">
                <TABLE1>26 1.1</TABLE1>
                <TABLE2>26 1.2</TABLE2>
                <TABLE3>26 1.3</TABLE3>
            </Query>
            <Query id="2">
                <TABLE21>26 2.1</TABLE21>
                <TABLE22>26 2.2</TABLE22>
                <TABLE23>26 2.3</TABLE23>
            </Query>
        </Report>
    </Connection>
</ShopArea>

生成所需的正确结果（查询子元素的所有不同名称的元素）：

TABLE1
TABLE2
TABLE3
TABLE21
TABLE22
TABLE23

II。 XSLT 2.0：此转换使用 ：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*/*">
     <xsl:for-each-group select="Report/Query/*"
                         group-by="name()">
      <xsl:sequence select="current-grouping-key(), '
'"/>
     </xsl:for-each-group>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>