是否可以使用鼠标向下和向上事件来模拟鼠标单击？

Question

之前的一个问题引起了我的思考。是否可以通过先触发 MOUSE_DOWN 再触发 MOUSE_UP 来模拟 MouseEvent.CLICK 的触发。

根据 Adob​​e 的文档。 “...要发生单击事件，它必须始终按发生顺序跟随这一系列事件：mouseDown 事件，然后是 mouseUp。这两个事件的目标对象必须相同；否则单击事件不会发生在 mouseDown 或 mouseUp 事件之间随时可以发生任意数量的其他鼠标事件； http://help.adobe .com/en_US/FlashPlatform/reference/actionscript/3/flash/display/InteractiveObject.html#event:click

从我的测试来看，CLICK 事件不是从 ActionScript 3 事件队列构造的。或者代码有问题吗？

请参阅：

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

[SWF(backgroundColor="0xFFFFFF", frameRate="30", width="800", height="600")]

public class Test extends Sprite
{
    private var spr:Sprite = new Sprite();
    public function Test()
    {
        trace("Test()");
        this.addEventListener(Event.ADDED_TO_STAGE,init);
    }
    public function init(e:Event):void
    {
        trace("init()");
        spr.graphics.beginFill(0xFF0000);
        spr.graphics.drawRect(0,0,200,80);
        spr.graphics.endFill();
        addChild(spr);
        addEventListener(Event.ENTER_FRAME, onEnterFrame);
        spr.addEventListener(MouseEvent.CLICK, onClick);
    }
    private var tick:int = 0;
    private function onEnterFrame(e:Event):void
    {
        if (tick == 1) spr.dispatchEvent(new MouseEvent(MouseEvent.MOUSE_DOWN,true,false));
        if (tick == 2) spr.dispatchEvent(new MouseEvent(MouseEvent.MOUSE_UP,true,false));
        if (tick == 3) spr.dispatchEvent(new MouseEvent(MouseEvent.CLICK,true,false));
        tick++;
    }
    private function onClick(e:MouseEvent):void
    {
        trace("onClick() MouseEvent.CLICK dispatched"); 
    }
}
}

我应该得到两个“onClick()”事件，而不是一个。

Answer 1

不能的原因是所有三种类型都是由插件创建的，并且彼此不依赖。

当您按下交互式对象时，MouseEvent.MOUSE_DOWN 就会被触发。
一旦释放鼠标，MouseEvent.MOUSE_UP 就会被触发，它不依赖于在同一 InteractiveObject 中启动 MOUSE_DOWN 的鼠标单击。
仅当两个事件发生在同一对象中且光标在鼠标按下和鼠标松开之间的时间间隔内没有离开该对象时，才会触发 MouseEvent.CLICK。

所以你可以看到有一个简单的情况，甚至两个，其中 MOUSE_DOWN 和 MOUSE_UP 都被触发，但 CLICK 没有被调用，因为该事件不是 CLICK。

此外，当只需要一个鼠标事件时，只需分派 MouseEvent.CLICK 事件的能力就无需通过触发多个鼠标事件来创建虚假的用户交互。如果必须跟踪鼠标按下侦听器中单击的每个对象，以检查鼠标向上是否也应该触发单击，那就很尴尬了。当 ROLL_OUT 事件发生时，您还需要删除引用。

简而言之，CLICK 事件确实比 MOUSE_DOWN 和 MOUSE_UP 事件多得多。它还管理事件在同一显示对象上连续发生而无需离开该对象。当这种情况发生时，并且仅当这种情况发生时，闪存才会调度 CLICK 事件。

Answer 2

这是不可能的，这段代码：

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.KeyboardEvent;
    import flash.events.MouseEvent;

    /**
     * ...
     * @author www0z0k
     */
    public class Main extends Sprite {

        public function Main():void {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            stage.addEventListener(MouseEvent.CLICK, onClick);
            stage.addEventListener(KeyboardEvent.KEY_DOWN, onStageKeyDown);
        }

        private function onStageKeyDown(e:KeyboardEvent):void {
            trace('pressed');
            stage.dispatchEvent(new MouseEvent(MouseEvent.MOUSE_DOWN));
            stage.dispatchEvent(new MouseEvent(MouseEvent.MOUSE_UP));           
            stage.dispatchEvent(new MouseEvent(MouseEvent.CLICK));          
        }

        private function onClick(e:MouseEvent):void{
            trace('clicked');
        }       
    }   
}

输出只是：

按下
点击

按下键盘上的某个键后

Answer 3

不确定闪存的这一点。但是当我学习windows MFC时，却一无所知。我所做的是先发送 WM_MOUSEDOWN，然后在短暂的延迟后发送 WM_MOUSEUP。它确实有效，并且按钮的视觉状态也发生了变化 - 无需单击任何鼠标！

Answer 4

如果我明白你在问什么，那么答案是肯定的。

我很好奇我是否过度简化了这里的解决方案，特别是在阅读您的代码尝试之后。 “模拟”鼠标点击非常简单。下面的代码在单击对象时输出两个“我已被单击”语句，而当您按下鼠标然后移出对象边界时则不会输出两个“我已被单击”语句。

这个类扩展了我在舞台上创建的 MovieClip，因此我不必编写盒子代码。

package  {

import flash.display.MovieClip;
import flash.events.MouseEvent;


public class clickMe extends MovieClip {


    public function clickMe() {
        // constructor code

        this.addEventListener(MouseEvent.CLICK, clicked);
        this.addEventListener(MouseEvent.MOUSE_DOWN, mDown);

    }

    private function clicked(e:MouseEvent):void{
        trace("I have been clicked");
        this.removeEventListener(MouseEvent.MOUSE_UP, clicked);
    }

    private function mDown(e:MouseEvent):void{
        this.addEventListener(MouseEvent.MOUSE_UP, clicked);
    }
}
}

在您的代码中，我认为问题在于您试图通过“onEnterFrame”运行事件侦听器分派，该事件每帧只会触发一个事件 - 永远不会触发两个事件。另外，在测试了您的代码之后，我不确定您试图使用“tick”变量来完成什么，因为您从未重置它。因此，MOUSE_UP 事件触发一次（当tick = 2 时，除非您按住鼠标），然后其他调度都不会再次触发。

Answer 5

不太清楚为什么每个人都制作这些复杂的尖峰。或者也许我只是在监督一些事情。

无论如何，这里有一个非常简单的方法来检查它：

import flash.events.MouseEvent;

stage.addEventListener(MouseEvent.CLICK, function(){
    trace( 'clicked' );
} );

stage.dispatchEvent( new MouseEvent( MouseEvent.MOUSE_DOWN ) );
stage.dispatchEvent( new MouseEvent( MouseEvent.MOUSE_UP ) );

答案是，“不，这是不可能的”......

并且可能应该紧随其后的是一个反问题：为什么会我想使用一系列 mousedown 和 mouseup 来模拟单击事件，当我也可以调度单击事件时？

我是一个面临生存危机的按钮吗？

或者只是出于好奇而提出的问题？但你知道那只猫发生了什么……对，但也许它是薛定谔的猫，这意味着在这个完全不相干的思路结束时，好奇心确实杀死了猫，但没有杀死猫。

除非猫已经脱离了盒子。

那么它可能就被浪费了。

你看，跳出框框思考可能会害死你。