Grails 中与同一域类的多个 hasMany 关系

Question

我正在使用 Grails，并且我有一个域模型，其中同一域类具有多个 hasMany 属性，如下所示：

static hasMany = [ posts : Post, likes : Post, dislikes : Post ]

我遇到的问题是，当我向帖子列表添加某些内容时，它也会以某种方式使将其放入喜欢和不喜欢的列表中。至少，当我迭代每个列表时，它看起来就是这样。

我认为问题在于我的 Post 域中也存在以下关系：

static belongsTo = [ contributer : Contributer ]

配置这些关系以使我的模型正常工作的最佳方法是什么？有什么建议吗？

---

@Wayne，

我也尝试使用你的测试，并且它成功通过了。所以，我唯一能想到的是我的 PostController 中的保存方法有问题。我粘贴了下面的相关代码（我正在使用 Spring Security Core 插件，我的 Contributer 类扩展了使用该插件创建的 User 类）：

@Secured(['IS_AUTHENTICATED_FULLY'])
def save = {
def props = [title:params.title, post:params.post,   category:Category.get(params.category.id)]

def user = Contributer.get(springSecurityService.principal.id)
def postInstance = new Post(props)

postInstance.contributer = user
if (postInstance.save(flush: true)) {
  flash.message = "${message(code: 'default.created.message', args: [message(code: 'post.label', default: 'Post'), postInstance.id])}"
  redirect(action: "show", id: postInstance.id)
}
else {
  render(view: "create", model: [postInstance: postInstance])
}
}

这里有什么突出的地方吗？

Answer 1

问题在于，Post 和 Contributor 之间存在一对多关系（帖子有作者，作者有很多帖子），以及 Post 和 Contributor 之间有两个多对多关系（帖子有很多喜欢者，喜欢很多帖子的喜欢者）（帖子有很多不喜欢的人，不喜欢的人不喜欢很多帖子）。 Post 中的 belongsTo 确实解释了该行为，但删除它并不能解决问题，只是会创建不同的问题。最终结果是 GORM 约定将达不到要求，因此您必须告诉 GORM 如何以不同的方式表现或建模。

有多种选择，但我首先想到的一个是将 Vote 与 Post 分开建模，以便贡献者 hasMany likeVotes 和 hasMany dislikeVotes

class Vote {

   // for illustration here, you need to think about the 
   // cascading behavior that makes sense and model it if you decide 
   // to go this route. 
  belongsTo = [post, contributor] 

}

class LikeVote extends Vote {
}

class DislikeVote extends Vote {
}

GORM 会将其建模为一张投票表，带有区分喜欢和不喜欢的区分栏；这将使您消除喜欢、不喜欢和撰写的帖子之间的冲突。

然后在 Contributor 中

 hasMany = [likes:LikeVote, dislikes:DislikeVote, posts:Post]

关系现在就清晰了：

1. 帖子有很多喜欢的投票
2. 帖子有很多不喜欢的投票
3. 贡献者有很多喜欢的投票
4. 贡献者有很多不喜欢的投票
5. 帖子有一个贡献者
6. 贡献者有很多帖子

GORM 可以理解这些关系，并且会做出适当的行为。

如果您不喜欢此选项，下一步是为您的数据库结构指定自定义映射，然后使用 mappedBy 来区分各种关系。如果您绝对希望贡献者以三种不同的方式直接与帖子相关，则可以采用这种方法。

Answer 2

在域类中使用 staticmappedBy

例如：

在多侧域对象 (Contributer.groovy) 中：

static hasMany = [ posts : Post, likes : Post, dislikes : Post ]
static mappedBy = [posts: "postsContributer", likes: "likesContributer", dislikes: "dislikesContributer"]

在一侧域对象 (Post.groovy) 中>):

Class Post {

       static belongsTo = [ contributer : Contributer ]

       Contributer postsContributer
       Contributer likesContributer
       Contributer dislikesContributer

   ... 
}

Answer 3

不过，多 M:M 的标准方法是使用 joinTable，如 GRAILS-4884 中的建议。

Answer 4

你能展示失败的测试用例吗？我将我认为的情况放入 grails 1.3.7 项目中，测试通过了：

class Post {
    String text ="postal"
    static belongsTo = [ contributor : Contributor ]
    static constraints = { }
}
class Contributor {
    String name = "Big C"
    static hasMany = [ posts : Post, likes : Post, dislikes : Post ]
    static constraints = { }
}

// integration test
void testMultipleRel() {
    Contributor c = new Contributor().save()
    assertNotNull c

    Post p1 = new Post(text:"neutral")
    Post p2 = new Post(text:"like")
    Post p3 = new Post(text:"dislike")
    [p1,p2,p3].each {c.addToPosts(it).save()}
    assertNotNull p1
    assertNotNull p2
    assertNotNull p3

    assertNull c.likes
    assertNull c.dislikes

    c.addToLikes(p2)
    c.addToDislikes(p3)

    assertEquals ([p1, p2, p3] as Set, c.posts as Set)
    assertEquals ([p2]         as Set, c.likes as Set)
    assertEquals ([p3]         as Set, c.dislikes as Set)

}

Answer 5

尝试切换到多对多关系并定义映射域类。在这个映射域类中，您可以指定关系的类型；喜欢、不喜欢或作者。

class Contributor {
    static hasMany = [contributorPosts:ContributorPost]
}

class ContributorPost {
    Post post
    Contributor contributor
    Boolean like
    Boolean dislike
    Boolean author
}

class Post {
    static hasMany = [contributorPosts:ContributorPost]
}

您可以在这里查看 http://www.grails.org/Many -to-Many+Mapping+without+Hibernate+XML 了解有关多对多映射域类的更多信息。

Answer 6

这应该有效：

static hasMany = [ posts : Post, likes : Post, dislikes : Post ]

static mapping = {
    posts joinTable: [name: 'contributor_posts']
    likes joinTable: [name: 'contributor_likes']
    dislikes joinTable: [name: 'contributor_dislikes']
}