URLLoader如何获取已加载的URL？

Question

使用 URLLoader 是否可以获取已加载文件的文件名？

public function loadCSS():void {
    var urlLoader:URLLoader = new URLLoader();
    urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
    urlLoader.load(new URLRequest("cssFile1"));
    urlLoader.load(new URLRequest("cssFile2"));
    urlLoader.load(new URLRequest("cssFile3"));
}

private function urlLoader_complete(evt:Event):void {

    // *****How can I get the file name here?
    var css:String = URLLoader(evt.currentTarget).data;
    // Do lots of stuff

}

Answer 1

首先，由于 load 方法是异步的，因此代码中的这三个调用将连续相互覆盖。唯一会导致调度 COMPLETE 事件的调用是最后一个调用。如果要异步加载文件，则需要为每个文件创建一个 URLLoader 实例。

其次，（以及您的问题的更多内容） URLLoader 类，允许您访问最初调用 load() 时使用的 URLRequest。

解决这个问题的一个简单方法是扩展 URLLoader。例如，如果您只需要 url:

public class MyURLLoader extends URLLoader
{
    private var _url:String;

    public function MyURLLoader(request:URLRequest=null)
    {
        super(request);
    }

    override public function load(request:URLRequest):void
    {
        super.load(request);
        _url = request.url;
    }

    public function get url():String
    {
        return _url;
    }
}

那么在您的代码中您仍然可以使用单个事件处理程序：

public function loadAllCSS():void {
    loadCSSFile("cssFile1");
    loadCSSFile("cssFile2");
    loadCSSFile("cssFile3");
}

private function loadCSSFile(cssURL:String):void {
    var urlLoader:MyURLLoader = new MyURLLoader();
    urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
    urlLoader.load(new URLRequest(cssURL));
}

private function urlLoader_complete(evt:Event):void {
    var cssURL:String = evt.target.url;  //now I know where this came from
    var css:String = evt.data;
}

Answer 2

创建三个 URLLoader。在完整的函数中，您可以检查事件目标的标识，以确定您从哪一个上获取事件，这将告诉您加载了哪个文件。您也可以使用三个不同的处理程序，具体取决于您想要如何分解代码。

文档并不清楚当您在同一个 URLLoader 上多次调用 load 时会发生什么，这（对我来说）意味着它不是明确定义的行为，您应该避免它。对于您的示例，文档没有指定您的事件处理程序是被调用一次还是三次，以及如果被调用多次，数据是否每次都会不同。