AS3：不规则形状上的随机点

Question

我有一个不规则形状的 MovieClip，如下所示：

我需要在此生成一个随机点形状。

我可以通过在边界框内生成点来使用强力，然后进行测试以查看它们是否位于不规则形状上。但是，我确信有一种更有效的方法来解决这个问题。

在不规则形状上生成随机点的最有效方法是什么？

Answer 1

您提到了 hitTest，但我认为您的意思是 hitTestPoint()。

如果是这样，一个函数会获取您提到的随机点，看起来有点像这样：

function getRandomPointsInClip(target:MovieClip,numPoints:int):Vector.<Point>{
    var points:Vector.<Point> = new Vector.<Point>(numPoints,true);
    var width:Number = target.width,height:Number = target.height;
    for(var i:int =  0; i < numPoints ; i++){
        var point:Point = new Point(target.x+Math.random() * width,target.y+Math.random() * height);
        if(target.hitTestPoint(point.x,point.y,true)) points[i] = point;//is the random coord inside ?
        else i = i-1;//nope, go back one step - > retry above until it is inside
    }
    return points;
}

我在评论中暗示的另一个涉及循环遍历对象的位图数据中的非透明像素。与之前的方法相反，此方法可以确保您不会有太多重复项，但这也意味着您对创建的点数量的控制较少，并且需要额外的内存来创建位图。尽管如此，出于文档目的，这里是函数：

function getGridPointsInClip(target:MovieClip,res:int,offset:Number = 3):Vector.<Point>{
    var points:Vector.<Point> = new Vector.<Point>();
    var x:int,y:int,alpha:int,w:int = int(target.width),h:int = int(target.height);
    var bmd:BitmapData = new BitmapData(w,h,true,0x00FFFFFF);bmd.draw(target);
    var pixels:Vector.<uint> = bmd.getVector(bmd.rect),numPixels:int = w*h;
    for(var i:int = 0; i < numPixels; i+=res) {
        x = i%bmd.width;
        y = int(i/bmd.width);
        alpha = pixels[i] >>> 24;
        if(alpha > 0) points.push(new Point(x+random(-offset,offset),y+random(-offset,offset)));
    }
    return points;
}
function random(from:Number,to:Number):Number {
    if (from >= to) return from;
    var diff:Number = to - from;
    return (Math.random()*diff) + from;
}

这是一个非常基本的测试：

var pts:Vector.<Point> = getRandomPointsInClip(mc,300);
//var pts:Vector.<Point> = getGridPointsInClip(mc,100,4);
for(var i:int = 0 ; i < pts.length; i++) drawCircle(pts[i].x,pts[i].y,3,0x009900);

function getRandomPointsInClip(target:MovieClip,numPoints:int):Vector.<Point>{
    var points:Vector.<Point> = new Vector.<Point>(numPoints,true);
    var width:Number = target.width,height:Number = target.height;
    for(var i:int =  0; i < numPoints ; i++){
        var point:Point = new Point(target.x+Math.random() * width,target.y+Math.random() * height);
        if(target.hitTestPoint(point.x,point.y,true)) points[i] = point;//is the random coord inside ?
        else i = i-1;//nope, go back one step - > retry above until it is inside
    }
    return points;
}
function getGridPointsInClip(target:MovieClip,res:int,offset:Number = 3):Vector.<Point>{
    var points:Vector.<Point> = new Vector.<Point>();
    var x:int,y:int,alpha:int,w:int = int(target.width),h:int = int(target.height);
    var bmd:BitmapData = new BitmapData(w,h,true,0x00FFFFFF);bmd.draw(target);
    var pixels:Vector.<uint> = bmd.getVector(bmd.rect),numPixels:int = w*h;
    for(var i:int = 0; i < numPixels; i+=res) {
        x = i%bmd.width;
        y = int(i/bmd.width);
        alpha = pixels[i] >>> 24;
        if(alpha > 0) points.push(new Point(x+random(-offset,offset),y+random(-offset,offset)));
    }
    return points;
}
function random(from:Number,to:Number):Number {
    if (from >= to) return from;
    var diff:Number = to - from;
    return (Math.random()*diff) + from;
}
function drawCircle(x:Number,y:Number,radius:Number,color:uint):void{
    graphics.lineStyle(1,color);
    graphics.drawCircle(x-radius,y-radius,radius);
}

HTH

Answer 2

如果您想到一些非斑点状的形状，很明显，检查随机像素，然后重试方法并不是一个真正的好方法。与形状区域相比，边界框区域可能会很大。

您可以采取的措施来提高效率获取形状的 BitmapData 的向量。它应该包含边界框的所有像素。 更新 - 现在如果我们可以选择一个随机点，如果它不在形状内，则将其从向量中删除，那就太好了。不幸的是，向量只包含像素的颜色，而不包含隐式的位置，并且只有在我们不改变向量的长度的情况下才是正确的。由于我们不需要知道实际颜色，因此可以省略所有透明像素并将内部像素的位置存储为向量中的值。这样我们就不需要为形状的每个像素创建一个新对象（这将非常昂贵！）。

var v:Vector.<uint> shapeBoxBitmap.getVector(shapeBoxBitmap.rect);
var pixelNum:int = v.length;
for(var i:uint = 0; i < pixelNum; i++) {
    if( v[i] && 0xFF000000 == 0) { // transparent pixel, outside off shape
       v.splice(i,1);
    } else {
      v[i] = i;
    }
}

//get random point
var randomPixel:int = v[Math.floor(Math.random()*v.length)];
var point:Point = new Point(randomPixel%shapeBitmap.width,int(randomPixel/shapeBitmap.width));