是否有将秒转换为英语的 CPAN 模块？

Question

是否有一个 CPAN 模块可以将秒数转换为人类可读的间隔英文描述？

secToEng( 125 ); # => 2 min 5 sec
secToEng( 129_600 ); # => 1 day 12 h

只要人类可读，格式并不重要。

我知道实施起来很简单。

Answer 1

事实证明 Time::Duration 正是这样做的。

$ perl -MTime::Duration -E 'say duration(125)'
2 minutes and 5 seconds
$ perl -MTime::Duration -E 'say duration(129_700)'
1 day and 12 hours

从剧情简介来看：

Time::Duration - 持续时间的四舍五入或精确的英文表达

在程序中的使用示例，以记录其运行时结束：

我的 $start_time = time();
使用时间::持续时间；
# 然后事情花费了所有的时间，然后结束：
打印“运行时”，持续时间（time（） - $start_time），“。\ n”；

报告文件寿命的程序中的使用示例：

使用时间::持续时间；
我的 $file = 'that_file';
我的 $age = $^T - (stat($file))[9]; # 9 = 修改时间
print "$file 已修改", ago($age);

Answer 2

可以使用 DateTime：

#!/usr/bin/env perl

use strict;
use warnings;

use DateTime;
use Lingua::EN::Inflect qw( PL_N );

my $dt = DateTime->from_epoch( 'epoch' => 0 );
$dt = $dt->add( 'seconds' => 129_600 );
$dt = $dt - DateTime->from_epoch( 'epoch' => 0 );

my @date;
push @date, $dt->days . PL_N( ' day', $dt->days ) if $dt->days;
push @date, $dt->hours . PL_N( ' hour', $dt->hours ) if $dt->hours;
push @date, $dt->minutes . PL_N( ' minute', $dt->minutes ) if $dt->minutes;
push @date, $dt->seconds . PL_N( ' second', $dt->seconds ) if $dt->seconds;

print join ' ', @date;

输出

1 day 12 hours

Answer 3

从 Perl v5.9.5 开始，模块 Time::Seconds 和 Time::Piece 是核心 Perl 发行版的一部分。因此您无需安装额外的模块即可使用它们。

perl -MTime::Seconds -e 'my $s=125; my $ts=new Time::Seconds $s; print $ts->pretty, "\n"'
# 2 minutes, 5 seconds

perl -MTime::Seconds -e 'my $s=129_600; my $ts=Time::Seconds->new($s); print $ts->pretty, "\n"'
# 1 days, 12 hours, 0 minutes, 0 seconds

您还可以使用诸如 $ts->weeks、$ts->mines 等内容。

Answer 4

我不久前找不到这样的代码，所以我写了这两个例程。第二个子程序使用第一个子程序并执行您正在寻找的操作。

#-----------------------------------------------------------
# format_seconds($seconds)
# Converts seconds into days, hours, minutes, seconds
# Returns an array in list context, else a string.
#-----------------------------------------------------------

sub format_seconds {
    my $tsecs = shift;

    use integer;
    my $secs  = $tsecs % 60;
    my $tmins = $tsecs / 60;
    my $mins  = $tmins % 60;
    my $thrs  = $tmins / 60;
    my $hrs   = $thrs  % 24;
    my $days  = $thrs  / 24;

    if (wantarray) {
        return ($days, $hrs, $mins, $secs);
    }

    my $age = "";
    $age .= $days . "d " if $days || $age;
    $age .= $hrs  . "h " if $hrs  || $age;
    $age .= $mins . "m " if $mins || $age;
    $age .= $secs . "s " if $secs || $age;

    $age =~ s/ $//;

    return $age;
}

#-----------------------------------------------------------
# format_delta_min ($seconds)
# Converts seconds into days, hours, minutes, seconds
# to the two most significant time units.
#-----------------------------------------------------------

sub format_delta_min {
    my $tsecs = shift;

    my ($days, $hrs, $mins, $secs) = format_seconds $tsecs;

    # show days and hours, or hours and minutes, 
    # or minutes and seconds or just seconds

    my $age = "";
    if ($days) {
        $age = $days . "d " . $hrs . "h";
    } 
    elsif ($hrs) {
        $age = $hrs . "h " . $mins . "m";
    } 
    elsif ($mins) {
        $age = $mins . "m " . $secs . "s";
    }
    elsif ($secs) {
        $age = $secs . "s";
    }

    return $age;
}

Answer 5

DateTime 模块就是您想要的。

DateTime::Duration 和 DateTime::Format::Duration 将满足您的需要。