使用 Windows Batch 脚本在 FOR 循环中计数

Question

谁能解释一下吗？我可以使用 Windows 命令提示符进行循环计数，使用此方法：

SET /A XCOUNT=0
:loop
SET /A XCOUNT+=1
echo %XCOUNT%
IF "%XCOUNT%" == "4" (
  GOTO end
) ELSE (
  GOTO loop
)
:end

但此方法不起作用（它为文件中的每一行打印出“1”）。它的行为就像变量超出范围：

SET /A COUNT=1
FOR /F "tokens=*" %%A IN (config.properties) DO (
  SET /A COUNT+=1
  ECHO %COUNT%
)

Answer 1

它不起作用，因为整个 for 循环（从 for 到最后的右括号，包括之间的命令those) 会在遇到时、在开始执行之前进行评估。

换句话说，在运行循环之前，%count% 被替换为其值 1。

您需要的是这样的：

setlocal enableextensions enabledelayedexpansion
set /a count = 1
for /f "tokens=*" %%a in (config.properties) do (
  set /a count += 1
  echo !count!
)
endlocal

使用 ! 而不是 % 的延迟扩展将为您提供预期的行为。另请参阅此处。

---

另请记住，setlocal/endlocal 实际上限制了内部更改的范围，以便它们不会泄漏。如果您想在 endlocal 之后使用 count ，则必须使用因您所遇到的问题而成为可能的“技巧”：

endlocal && set count=%count%

假设内部范围内的 count 已变为 7。因为整个命令在执行之前被解释，所以它实际上变成：

endlocal && set count=7

然后，当它被执行时，内部作用域被关闭，将 count 返回到它的原始值。但是，由于将 count 设置为 7 发生在外部作用域中，因此它实际上泄漏了您需要的信息。

您可以将多个子命令串在一起以泄漏您需要的尽可能多的信息：

endlocal && set count=%count% && set something_else=%something_else%

Answer 2

for a = 1 到 100 步骤 1

Windows 中的命令行。如果在批处理文件中运行，请使用 %%a。

    for /L %a in (1,1,100) Do echo %a 

Answer 3

这是生成所有 10.xxx 地址的批处理文件

@echo off

SET /A X=0
SET /A Y=0
SET /A Z=0

:loop
SET /A X+=1
echo 10.%X%.%Y%.%Z%
IF "%X%" == "256" (
 GOTO end
 ) ELSE (
 GOTO loop2
 GOTO loop
 )


:loop2
SET /A Y+=1
echo 10.%X%.%Y%.%Z%
IF "%Y%" == "256" (
  SET /A Y=0
  GOTO loop
  ) ELSE (
   GOTO loop3
   GOTO loop2
 )


:loop3

SET /A Z+=1
echo 10.%X%.%Y%.%Z%
IF "%Z%" == "255" (
  SET /A Z=0
  GOTO loop2
 ) ELSE (
   GOTO loop3
 )

:end