如何创建 AppleScript 来循环浏览 BBEdit 文档并将“-”移动到从数字的末尾到开头？

Question

我有一个脏报告文件，其中包含格式不正确的负数。最终目标是将这些导入 Excel 进行分析。我在导入 Excel 之前使用 BBEdit 清理报告。我想创建一个苹果脚本来循环遍历报告并将“-”从数字后面移到前面。

脏报告示例行：

B-EXCAL 02 3684        2.0000-      49.02-       108.00-        58.98-  54.6-
B-MISMH 09-3300       33.0000      722.91       1353.00        630.09   46.6 

所需的输出：

B-EXCAL 02 3684       -2.0000      -49.02       -108.00        -58.98  -54.6
B-MISMH 09-3300       33.0000      722.91       1353.00        630.09   46.6 

我有 JavaScript 和 VBScript 经验，因此我想象脚本的工作方式类似于此伪脚本：

Get contents of current window from BBEdit
   for each word in contents
       if char(len(word)) = "-"
           newWord = "-" + rightTrim(word, 1) 
           replace(word, newWord)
       end if
   end for
end

这是我第一次使用 AppleScript，我完全不知所措。

感谢您的帮助/

Answer 1

我不确定您是否需要 AppleScript。 BBEdit 的查找/替换窗口可以解决这个问题吗？尝试以下操作：

Find: ([0-9\.]+)\-

Replace: \-\1

“Grep”和“Wrap around”应该是“替换”文本区域下方唯一选择的内容。然后单击“全部替换”。

如果您需要一次对一堆报告执行此操作，请使用相同的查找/替换模式进行多文件搜索。如果我没有正确理解你的问题，请告诉我，但我认为你可以在没有 AppleScript 的情况下完成此任务。

Answer 2

试试这个。我假设您可以将 bbedit （或其他地方）中的文本作为变量“originalText”获取到 applescript 中。然后你必须将“fixedText”放回它所属的位置。注意：在我的代码中，我假设“制表符”字符分隔 origText 的每一行中的单词/列，因为 Michael J. Barber 目前已对其进行格式化。如果它是另一个字符（例如空格字符），那么您必须将代码中的单词 tab 更改为 space。

set originalText to "B-EXCAL 02 3684    2.0000- 49.02-  108.00- 58.98-  54.6-
B-MISMH 09-3300 33.0000 722.91  1353.00 630.09  46.6"
set fixedText to fixNegativeSigns(originalText)

on fixNegativeSigns(theText)
    set listText to paragraphs of theText
    set fixedText to ""

    set {tids, text item delimiters} to {text item delimiters, tab}
    repeat with i from 1 to count of listText
        set listItems to {}
        set thisList to text items of (item i of listText)
        repeat with j from 1 to count of thisList
            set thisItem to item j of thisList
            if text -1 of thisItem is "-" then
                set thisItem to "-" & text 1 thru -2 of thisItem
            end if
            set end of listItems to thisItem
        end repeat
        set fixedText to fixedText & (listItems as text) & character id 10
    end repeat
    set text item delimiters to tids
    return text 1 thru -2 of fixedText
end fixNegativeSigns

注意：在测试上面的代码时，您应该将其复制/粘贴到 Applescript 编辑器中。您必须修复originalText中的制表符，因为它们在复制/粘贴后无法保留。因此，删除单词/列之间的空格并插入制表符。然后代码就可以正常工作了。