Prolog 元谓词：将谓词应用于列表，传递常量

Question

假设您需要一个谓词将列表中的 Number1 替换为 Number2。
当然，为此编写一个递归函数很简单，例如：

replace(_,_,[],[]).
replace(N1,N2,[N1|T], [N2|NT]):-
    replace(N1,N2,T,NT).
replace(N1,N2,[H|T],[H|NT]):-
    replace(N1,N2,T,NT).

我的问题是是否有一种方法可以使用 maplist/x （或类似的元谓词）来做到这一点。
人们可以使用全局变量来做到这一点，例如：

replace(N1,N2,L1,L2):-
    nb_setval(numbers,[N1,N2]),
    maplist(replace_in,L1,L2).

replace_in(N1,N2):-
    nb_getval(numbers,[N1,N2]).
    replace_in(X,X).

另一种想法是创建相同数字 List_of_N1 和 List_of_N2 的列表，并将它们传递给 maplist/4。
他们对我来说都不有吸引力，有什么想法吗？

Answer 1

顺便说一句：根据您给定的定义，请考虑例如显然无意的第二个解决方案：

?- replace(1, 4, [1,2,3], Ls).
Ls = [4, 2, 3] ;
Ls = [1, 2, 3] ;
false.

至于实际问题，请考虑：

replace(A, B, X, Y) :- ( X == A -> Y = B ; Y = X ).

示例查询：

?- maplist(replace(1,4), [1,2,3], Ls).
Ls = [4, 2, 3].

---

---

对于 逻辑纯度，我推荐一个真正的关系版本，可以在各个方向使用：

replacement(A, B, A, B).
replacement(A, _, X, X) :- dif(A, X).

示例：

?- maplist(replacement(a,b), [X], Rs).
Rs = [b],
X = a ;
Rs = [X],
dif(X, a).

Answer 2

这个怎么样：

replace(N1,N2,L1,L2):-
    maplist(replace_in,[N1-N2-T|T], L1,L2).

replace_in(N1-N2-T, X, Y):-
  (X=N1 -> Y=N2 ; Y=X),
  (T=[N1-N2-L|L] ; T=[]).