Scala：你可以使用“foo match { bar }”吗？在没有括号的表达式中？

Question

这里为什么需要括号？我应该知道一些优先规则吗？

scala> 'x' match { case _ => 1 } + 1
<console>:1: error: ';' expected but identifier found.
       'x' match { case _ => 1 } + 1
                                 ^

scala> ('x' match { case _ => 1 }) + 1
res2: Int = 2

谢谢！

Answer 1

正如 Agilesteel 所说，匹配不被视为简单的表达式，if 语句也不被视为简单的表达式，因此您需要用括号将表达式括起来。来自 Scala 语言
规范，6 表达式，p73，匹配是一个 Expr，就像一个 if 一样。 + 运算符两侧仅接受 SimpleExpr。

要将 Expr 转换为 SimpleExpr，必须用 () 将其括起来。

为了完整性而复制：

Expr ::= (Bindings | id | ‘_’) ‘=>’ Expr
    | Expr1
Expr1 ::= ‘if’ ‘(’ Expr ‘)’ {nl} Expr [[semi] else Expr]
    | ‘while’ ‘(’ Expr ‘)’ {nl} Expr
    | ‘try’ ‘{’ Block ‘}’ [‘catch’ ‘{’ CaseClauses ‘}’] [‘finally’ Expr]
    | ‘do’ Expr [semi] ‘while’ ‘(’ Expr ’)’
    | ‘for’ (‘(’ Enumerators ‘)’ | ‘{’ Enumerators ‘}’) {nl} [‘yield’] Expr
    | ‘throw’ Expr
    | ‘return’ [Expr]
    | [SimpleExpr ‘.’] id ‘=’ Expr
    | SimpleExpr1 ArgumentExprs ‘=’ Expr
    | PostfixExpr
    | PostfixExpr Ascription
    | PostfixExpr ‘match’ ‘{’ CaseClauses ‘}’
PostfixExpr ::= InfixExpr [id [nl]]
InfixExpr ::= PrefixExpr
    | InfixExpr id [nl] InfixExpr
PrefixExpr ::= [‘-’ | ‘+’ | ‘~’ | ‘!’] SimpleExpr
SimpleExpr ::= ‘new’ (ClassTemplate | TemplateBody)
    | BlockExpr
    | SimpleExpr1 [‘_’]
SimpleExpr1 ::= Literal
    | Path
    | ‘_’
    | ‘(’ [Exprs] ‘)’
    | SimpleExpr ‘.’ id s
    | SimpleExpr TypeArgs
    | SimpleExpr1 ArgumentExprs
    | XmlExpr
Exprs ::= Expr {‘,’ Expr}
BlockExpr ::= ‘{’ CaseClauses ‘}’
    | ‘{’ Block ‘}’
Block ::= {BlockStat semi} [ResultExpr]
ResultExpr ::= Expr1
    | (Bindings | ([‘implicit’] id | ‘_’) ‘:’ CompoundType) ‘=>’ Block
Ascription ::= ‘:’ InfixType
    | ‘:’ Annotation {Annotation}
    | ‘:’ ‘_’ ‘*’

Answer 2

经过对 Scala 规范的一些检查后，我想我可以尝试一下。
如果我错了请纠正我。

首先，if 或 match 被定义为 Expr - 表达式。

您正在尝试创建一个中缀表达式（通过在两个表达式之间使用运算符来定义）

但是 规范（第 3.2.8 节）指出：

所有类型中缀运算符具有相同的优先级；括号必须
用于分组

它还指出：

在连续类型中缀操作序列中 t0 op1 t1 op2 。 。
.opn tn，所有运算符 op1, . 。 。 , opn 必须具有相同的
关联性。如果它们都是左关联的，则顺序为
解释为 (...(t0 op1 t1) op2...) opn tn。

所以我的看法是 Scala 不知道首先要减少什么：匹配或方法“+”调用。

看看这个答案

如果我是的话请纠正我错误的。

Answer 3

匹配表达式不被视为简单表达式。这是一个类似的例子：

scala> val foo = "bar" + if(3 < 5) 3 else 5   // does not compile
scala> val foo = "bar" + (if(3 < 5) 3 else 5) // does compile

显然你不能在任何你想要的地方编写复杂的表达式。我不知道为什么，希望对此主题有更多了解的人能给您更好的答案。