如何从 VBscript 中的字符串中删除字符

Question

我是 vbscript 和 Stack Overflow 的新手，确实需要一些帮助。

目前，我正在尝试格式化从图像读取并存储在变量中的电话号码。因为图像是“脏”的，所以会出现额外的字符，例如句号或括号。我已经尽可能地限制了该字段，以防止拾取额外的字符，但是唉！

例如我想将“,123.4567890”转换为“123 456 7890”（不包括双引号）。问题是我不知道可能会选取哪些额外的字符，从而排除了简单的替换。

我的逻辑是删除所有非数字字符，从左侧开始，在第三个数字后插入一个空格，在第六个数字后插入一个空格。

任何帮助都会很棒，如果需要，请随时询问更多信息。

Answer 1

欢迎来到堆栈溢出。您可以使用 Regex 和 使用 连接 各部分中功能。

例如：

Dim sTest
sTest = ",123.4567890"

With (New RegExp)
    .Global = True
    .Pattern = "\D" 'matches all non-digits
    sTest = .Replace(sTest, "") 'all non-digits removed
End With

WScript.Echo Mid(sTest, 1, 3) & " "& Mid(sTest, 4, 3) & " "& Mid(sTest, 7, 4)

或完全使用正则表达式（通过第二个分组模式）：

Dim sTest
sTest = ",123.4567890"

With (New RegExp)
    .Global = True
    .Pattern = "\D" 'matches all non-digits
    sTest = .Replace(sTest, "") 'all non-digits removed
    .Pattern = "(.{3})(.{3})(.{4})" 'grouping
    sTest = .Replace(sTest, "$1 $2 $3") 'formatted 
End With

WScript.Echo sTest

Answer 2

使用第一个正则表达式来清除输入中的非数字，第二个正则表达式使用布局组来清除：

Function cleanPhoneNumber( sSrc )
  Dim reDigit : Set reDigit = New RegExp
  reDigit.Global  = True
  reDigit.Pattern = "\D"
  Dim reStruct : Set reStruct = New RegExp
  reStruct.Pattern = "(.{3})(.{3})(.+)"
  cleanPhoneNumber = reStruct.Replace( reDigit.Replace( sSrc, "" ), "$1 $2 $3" )
End Function ' cleanPhoneNumber