为什么这个苹果脚本似乎没有按预期工作？

Question

我正在使用自动化程序编写服务。它在任何应用程序中都不接收输入。

它所做的只是运行这个简单的脚本：

on run {input, parameters}
--FIRST BLOCK
    tell application "System Events"
        set app_name to name of the first process whose frontmost is true
    end tell
--SECOND BLOCK
    if (do shell script "defaults read com.apple.finder AppleShowAllFiles") is equal to "0" then
        do shell script "defaults write com.apple.finder AppleShowAllFiles 1"
    else
        do shell script "defaults write com.apple.finder AppleShowAllFiles 0"
    end if
--THIRD BLOCK
    do shell script "killall Finder"
    delay 0.5
--FOURTH BLOCK
    if (app_name is equal to "Finder") then
        tell application "Finder"
            activate
        end tell
    end if
end run

我将逐步引导您完成它：

第一个块：获取当前最前面的应用程序的名称并将其存储在变量app_name.

第二个块：根据其值打开或关闭隐藏文件变量。

第三块：运行killall Finder重新启动Finder，使第二块的切换生效。暂停0.5秒，不知何故这是必要的（不知道为什么，但如果没有这个，下一条指令将被忽略）。

第四块：检查变量app_name是什么。如果它等于Finder，这意味着在启动脚本时finder处于活动状态，因此再次激活Finder（killall Finder将其留在后台）。

问题：一切都按预期工作，但有一件事：在 Finder 中使用此服务时，Finder 不会再次激活。

有人可能会说第四个块中的代码一定有问题，但我已经做了一些实验来证明一切都按预期工作：

当我用 not equalequal 时code> 并从非 Finder 的任何应用程序运行脚本，Finder 确实会按应有的方式激活。

所以看来只有当 Finder 位于前面时触发脚本时才会出现问题。

（这就是服务应该做的：在任何应用程序中，切换 Finder 中隐藏文件的可见性。当 Finder 位于前面时，执行脚本后它应该位于前面，当另一个应用程序位于前面时，此应用程序应该位于前面应该仍然在前面。）

我在 Lion 上。

Answer 1

我以前也遇到过这个。基本上，您是说，当 Finder 位于最前面时运行此命令时，Finder 并不是真正位于最前面。这是真的，因为你说这是一项自动化服务。我相信自动化程序是由名为“Automator Runner”的应用程序运行的。因此，实际上一旦服务运行，Automator Runner 就会成为最前面的。请注意，它是一个不露面的应用程序，因此您看不到它是最前面的，但它确实是最前面的。因此，当您检查 Finder 是否位于最前面时，它从来都不是。这有道理吗？我在运行 applescript 时看到同样的情况，因为它们是使用 Applescript Runner 运行的。

那么如何解决这个问题呢？这是一个想法。将此作为您的第一个块，看看它是否有帮助...

tell application "System Events"
    set app_name to name of the first process whose frontmost is true
    if app_name is "Automator Runner" then
        set visible of process "Automator Runner" to false
        set app_name to name of first process whose frontmost is true
    end if
end tell

注意：我不确定 Automator Runner 将是最前面的进程。它可能是其他名称，例如自动操作的名称。但是您可以确定其他东西是最前面的，因为自动操作正在运行......所以如果我的代码不起作用，那么您只需找出自动操作运行时正在运行的进程的名称并将其放入进入代码。您始终可以在代码中放置一个“显示对话框”来显示最前面进程的名称。

另一个提示。一般来说，如果可以使用 QUIT 命令代替，我不喜欢使用 KILLALL 命令。 Quit 专为 Mac 设计，可确保正常停止操作。幸运的是，Finder 有一个退出命令。在你的第三个和第四个块上尝试这个。您会看到，如果 Finder 位于最前面，那么我们会激活它，这会使其再次位于最前面，但如果不是，那么我们会启动它，这样它至少会再次运行，但不会出现在最前面。

-- quit the Finder
tell application "Finder" to quit

-- delay until the Finder quits
repeat
    try
        tell application "System Events" to get first process whose name is "Finder"
        delay 0.1
    on error
        exit repeat
    end try
end repeat

-- restart the Finder
if (app_name is equal to "Finder") then
    tell application "Finder" to activate
else
    tell application "Finder" to launch
end if

编辑：看来您的第 2 步不正确。您需要使用“ON”或“OFF”而不是0或1。试试这个...

if (do shell script "defaults read com.apple.finder AppleShowAllFiles") is equal to "ON" then
    do shell script "defaults write com.apple.finder AppleShowAllFiles OFF"
else
    do shell script "defaults write com.apple.finder AppleShowAllFiles ON"
end if

Answer 2

对 @regulus6633 的脚本进行轻微修改可以在我的机器上运行：

-- restart the Finder
tell application "Finder" to launch      # always launch
if (app_name is equal to "Finder") then
  tell application "Finder" to activate  # activate separately
end if

我必须承认我并不完全确定原因和方式 - 启动和activate 命令在 Finder 的情况下似乎不够......