节点、会话存储删除过期会话

Question

我正在尝试为express.js 节点应用程序实现会话存储 我的问题是：

1. 如何删除具有浏览器会话生存期的 cookie（根据连接文档标记有 expires = false）
2. 我应该将会话数据存储为 json 字符串还是直接存储为对象，

这是我想出的咖啡脚本，所以到目前为止，我使用猫鼬，这是我为应用程序选择的 orm

    express  = require 'express'
    mongoose = require "mongoose"
    util     = require "util"

    # define session schema
    SessionSchema = new mongoose.Schema
      sid     : { type: String, required: true, unique: true }
      data    : { type: String, default: '{}' }
      expires : { type: Date, index: true }

    module.exports =
    class SessionStore extends express.session.Store
      constructor: (options) ->

        console.log "creating new session store"

        options ?= {}

        # refresh interval
        options.interval ?= 60000 

        options.url ?= "mongodb://localhost/session" 

        # create dedicated session connection
        connection = mongoose.createConnection options.url

        # create session model
        @Session = connection.model 'Session', SessionSchema

        # remove expired session every cycles
        removeExpires = => @Session.remove expires: { '$lte': new Date() }

        setInterval removeExpires, options.interval

      get: (sid, fn) ->
        @Session.findOne sid: sid, (err, session) ->
          if session?
            try
              fn null, JSON.parse session.data
            catch err
              fn err
          else
              fn err, session

      set: (sid, data, fn) ->

        doc =
            sid: sid
            data: JSON.stringify data
            expires:  data.cookie.expires 
        try
          @Session.update sid: sid, doc, upsert: true, fn
        catch err
          fn err

      destroy: (sid, fn) ->
        @Session.remove { sid: sid }, fn

      all: (fn) ->
        @Session.find { expires: { '$gte': new Date() } }, [ 'sid' ], (err, sessions) ->
          if sessions?
            fn null, (session.sid for session in sessions)
          else
            fn err

      clear: (fn) -> @Session.drop fn

      length: (fn) -> @Session.count {}, fn

Answer 1

我对 Node 还很陌生，所以对此持保留态度。

虽然不直接面向会话，但记住我的 dailyjs 教程将帮助我想有点。特别是他验证登录令牌的最后一段代码。

另外，我认为最好解析 JSON 并将其存储为对象。如果您预先进行解析，应该更容易以这种方式访问​​不同的 cookie 位。