使用 awk 检查不同行的变量

Question

我想使用 awk 将多行不同长度的值合并到一行（如果它们匹配）。在以下第一个字段的示例匹配值中， 将第二个字段中的值聚合到列表中。

输入，示例 csv：

222;a;DB;a
222;b;DB;a
555;f;DB;a
4444;a;DB;a
4444;d;DB;a
4444;z;DB;a

输出：

222;a|b
555;f
4444;a|d|z

如何编写 awk 表达式（可能是其他 shell 表达式）来检查第一个字段值是否与下一行/上一行匹配，然后打印第二个字段值的列表，这些值聚合并由管道？

Answer 1

awk '
  BEGIN {FS=";"}
  { if ($1==prev) {sec=sec "|" $2; }
    else { if (prev) { print prev ";" sec; };
           prev=$1; sec=$2; }}
  END { if (prev) { print prev ";" sec; }}'

根据您的要求，这会检查连续的行。

Answer 2

这个单线有用吗？

 awk -F';' '{a[$1]=a[$1]?a[$1]"|"$2:$2;} END{for(x in a) print x";"a[x]}' file

在这里测试：

kent$  cat a
222;a;DB;a
222;b;DB;a
555;f;DB;a
4444;a;DB;a
4444;d;DB;a
4444;z;DB;a

kent$  awk -F';' '{a[$1]=a[$1]?a[$1]"|"$2:$2;} END{for(x in a) print x";"a[x]}'  a
555;f
4444;a|d|z
222;a|b

如果你想保持排序，请在末尾添加 |sort 。

Answer 3

有点复杂，但可以完成工作：

awk -F';' \
'{
  if (a[$1]) {
    a[$1]=a[$1] "|" $2
  } else {
    a[$1]=$2
  }
 }
 END {
   for (k in a) {
     print k ";" a[k]
   }
 }' file

Answer 4

假设您已将字段分隔符 (-F) 设置为 ; ：

{
   if ( $1 != last ) { print s; s = ""; }
   last = $1;
   s = s "|" $2;
} END {
   print s;
}

第一行和第一个字符略有错误，但这是读者的练习:-)。两个简单的 if 就足以解决这个问题。

（编辑：错过了最后一行。）

Answer 5

这应该有效：

命令：

awk -F';' '{if(a[$1]){a[$1]=a[$1]"|"$2}else{a[$1]=$2}}END{for (i in a){print i";" a[i] }}' fil

输入：

222;a;DB;a
222;b;DB;a
555;f;DB;a
4444;a;DB;a
4444;d;DB;a
4444;z;DB;a

输出：

222;a|b
555;f
4444;a|d|z