如何添加在 OSX 上按预期工作的菜单项分隔符？

Question

在Windows平台上，使用VCL，当我们想在菜单中添加分隔符时，我们添加一个TMenuItem 带有 Caption := '-';

使用 FireMonkey，我们添加一个 TMenuItem 和 Text := '-';

它在 Windows 平台上按预期工作，带有 Text='-' 的项目显示为分隔符。

但是，当我在 OSX 上运行相同的应用程序时，减号可见...

我没有在 TMenuItem 上找到任何属性来指定它是 < strong>separator...

我尝试过使用 TMainMenu 和 TMenuBar (UseOSMenu := True|False;) 和我仍然有这个问题。

有想法创建一个真正的分隔符吗？（否则，我会检查操作系统并删除它，如果 OSX...）

Answer 1

这是 FireMonkey 中的一个错误。我相信他们会解决这个问题。但同时您可以使用下面的代码。在主窗体的 OnActivate 事件中调用过程 FixSeparatorItemsForMac。

不要忘记使用列表中的 mac 特定文件。

uses
...
  {$IFDEF MACOS}
  ,Macapi.ObjectiveC,MacApi.AppKit,MacApi.Foundation,FMX.Platform.Mac
  {$ENDIF}

{$IFDEF MACOS}

Procedure FixSeparatorItemsForMenuItem(MenuItem:NSMenuItem);
var i:Integer;
    subItem:NSMenuItem;
begin
  if (MenuItem.hasSubmenu = false) then exit;
  for i := 0 to MenuItem.submenu.itemArray.count -1 do
  begin
    subItem := MenuItem.submenu.itemAtIndex(i);
    if (subItem.title.isEqualToString(NSSTR('-'))= true) then
    begin
      MenuItem.submenu.removeItemAtIndex(i);
      MenuItem.submenu.insertItem(TNSMenuItem.Wrap(TNSMenuItem.OCClass.separatorItem),i);
    end else begin
      FixSeparatorItemsForMenuItem(subItem);
    end;
  end;
end;

Procedure FixSeparatorItemsForMac;
var NSApp:NSApplication;
    MainMenu:NSMenu;
    AppItem: NSMenuItem;
    i: Integer;
begin
  NSApp := TNSApplication.Wrap(TNSApplication.OCClass.sharedApplication);
  MainMenu := NSApp.mainMenu;
  if (MainMenu <> nil) then
  begin
    for i := 0 to MainMenu.itemArray.count -1 do
    begin
      AppItem := mainMenu.itemAtIndex(i);
      FixSeparatorItemsForMenuItem(AppItem);
    end;

  end;
end;
{$ENDIF}

Answer 2

我从来没有为 Mac 编程过，而且我也没有 Mac，但出于好奇，我找到了一些关于它的 Apple 文档。

菜单分隔符项是一个禁用的空白菜单项，也许您可​​以用它来伪造：

分隔符项目

返回一个菜单项，用于分隔菜单的逻辑组
命令。
+ (NSMenuItem *)separatorItem 返回值

用于分隔菜单命令逻辑组的菜单项。

讨论

此菜单项已禁用。默认分隔符项是空格。

（来自：http://developer.apple.com/library/mac/#documentation/Cocoa/Reference/ApplicationKit/Classes/NSMenuItem_Class/Reference/Reference.html#//apple_ref/doc/c_ref/NSMenuItem)

Answer 3

我没有测试这个的设施，但值得一试。

默认情况下，FireMonkey 创建自己的完全样式菜单，但将 TMenuBar.UseOSMenu 属性设置为 true 并使用操作系统调用来创建菜单。

然后，您可以将其与已经讨论过的创建 Cocoa 菜单的建议结合起来。

来自http://docwiki.embarcadero.com/RADStudio/en/FireMonkey_Application_Design#Menus ：

“将 TMenuBar.UseOSMenu 属性设置为 True 会导致 FireMonkey 通过操作系统调用创建菜单树，从而生成本机菜单。在 Windows 上，此菜单位于父窗体的顶部，并使用当前的外观主题显示。在 Mac OS X 上，只要应用程序获得焦点，菜单就会显示在主屏幕顶部的全局菜单栏中。”