Delphi：全局更改ADO命令超时

Question

我们有一个巨大的 Delphi 2005 应用程序，其中包含大量 ADO 组件（TADODataset、TADOStoredPROc、TADOCommand...），分布在数百个表单上。它们全部连接到单个 TADOConnection。

这些组件中的大多数将其 CommandTimeout 属性设置为默认值（30 秒），但少数将其设置为 5 分钟（300 秒），还有一些设置为永不超时（0 秒）。

我希望能够在应用程序范围内全局更改所有 ADO 组件的此设置。我更喜欢在运行时以编程方式执行此操作，以便在需要时可以在每次安装的基础上调整超时。

我希望在创建/附加 ADO 组件时可以在连接上找到一个全局事件，我可以在其中调整命令超时，或者破解我的方式将我的代码注入组件本身，但结果是空白。

我不想创建后代，因为我必须搜索/替换所有组件，并且如果我忘记使用后代而不是常规 ADO 组件，我的超时将不会遵循应用程序的其余部分。

有人知道我们如何做到这一点吗？

Answer 1

如果所有 ADO 组件都放置在窗体上，则可以使用 Screen.Forms 和 Screen.FormCount 属性迭代所有窗体。对于每个表单，迭代其 ComponentCount/Components 属性并检查 TADOCommand、TADODataSet、TADOQuery、TADOStoredProc 和 TADOTable。然后您可以根据需要设置超时时间。当然，如果您动态创建表单，则必须单独考虑这一点。

以下代码可能会指导您。

procedure SetADOTimeout(ATimeout: Integer);
var
  cmp: TComponent;
  frm: TForm;
  I: Integer;
  J: Integer;
begin
  for I := 0 to Screen.FormCount - 1 do begin
    frm := Screen.Forms[I];
    for J := 0 to frm.ComponentCount - 1 do begin
      cmp := frm.Components[J];
      if cmp is TADOCommand then
        TADOCommand(cmp).CommandTimeout := ATimeout
      else if cmp is TADODataSet then
        TADODataSet(cmp).CommandTimeout := ATimeout
      else if cmp is TADOQuery then
        TADOQuery(cmp).CommandTimeout := ATimeout
      else if cmp is TADOStoredProc then
        TADOStoredProc(cmp).CommandTimeout := ATimeout
      else if cmp is TADOTable then
        TADOTable(cmp).CommandTimeout := ATimeout;
    end;
  end;
end;

Answer 2

向所有阿根廷解决方案致以问候！

只需为您拥有的 TADOConnection 定义 OnWillExecute 事件处理程序并编写以下代码：

type
  TCustomADODataSetAccess = class(TCustomADODataSet);

procedure TYourDataModule.ADOConnectionWillExecute(...);
var
  i: Integer;
begin
  for i := 0 to ADOConnection.DataSetCount - 1 do
    TCustomADODataSetAccess(ADOConnection.DataSets[i]).CommandTimeout := Connection.CommandTimeout;
end;

这将为使用 ADO 连接的任何查询/表/存储过程设置命令超时。

Answer 3

根据文档，您可以使用 CommandCount 和 Commands 来查找附加到 TADOConnection 的所有打开组件。

您的问题可能是动态创建的表单。创建表单时，您需要找到要挂钩的“东西”，并检查该表单上的 ADO 组件。

如果您的表单源自自定义表单类，则可以在表单的构造函数 或OnCreate 事件中执行此操作。

如果没有，您可以查看 TApplicationEvents 并使用 TApplication 的 OnIdle 事件。

Answer 4

由于 CommandTimeout 是在 TCustomADODataset 类中引入的，因此您可以迭代每个表单/数据模块，找到 TCustomADODataset 及其后代（ADODataset、ADOTable、ADOQuery），然后设置属性。

procedure SetADOCommandTimeOut(aTimeOut: integer);
var
  i, j: integer;
begin
  for i:= 0 to Screen.FormCount-1 do
  begin
    for j:= 0 to Forms[i].ComponentCount-1 do
      if Forms[i].Components[j] is TCustomADODataset then
        TCustomADODataset1(Forms[i].Components[j]).CommandTimeOut:= aTimeOut;
  end;

  for i:= 0 to Screen.DataModuleCount-1 do
  begin
    for j:= 0 to Datamodules[i].ComponentCount-1 do
      if Datamodules[i].Components[j] is TCustomADODataset then
        TCustomADODataset1(Datamodules[i].Components[j]).CommandTimeOut:= aTimeOut;
  end;
end;

注意：TCustomADODataset1 与 TCustomADODataset 完全相同，只是它具有已发布的 CommandTimeOut 属性：

TCustomADODataset1 = class(TCustomADODataset)
published
  property CommandTimeOut;
end;

但它仅适用于已创建的表单/数据模块。如果您动态创建表单/数据模块，则每当创建新表单/数据模块时都必须应用它。
一种方法是覆盖主窗体中的通知，检查表单/数据模块的新创建，但这有点棘手，因为在创建时，所有组件尚未创建。你通过使用计时器延迟一段时间来欺骗它（我不知道更优雅的方法 - 只是为了展示这个想法）

Procedure TMainForm.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited;
  if (Operation = opInsert) and (
     ((AComponent is TForm) and not (aComponent is TMainForm)) // exclude MainForm 
     or (AComponent is TDataModule)
     ) then
  begin
    Timer1.Interval:= 2000; // 2 seconds ?
    Timer1.Enabled:= True;
  end;
end;

Procedure TMainForm.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled:= False;
  SetADOCommandTimeOut(MyTimeOut);
end;

Answer 5

您创建数据模块层次结构？如果是这样，您可以在您的族长表单上使用类似 Uwe 的答案的代码（所有其他数据模块都会继承）。