ActionScript 3：LoaderInfo COMPLETE 事件在 load() 和 loadBytes() 之后不会触发

Question

我正在尝试使用带有 Loader 对象的 ActionScript 加载 PNG 图像。这对于某些图像效果很好（INIT 和 COMPLETE 事件按预期触发），而对于其他图像则不然。我在这个帖子中读到 URLLoader 可能会有所帮助，所以我尝试了，之后使用 loadBytes() 函数。仍然不起作用：URLLoader 触发 COMPLETE 事件，但 LoaderInfo 对象不会。

我编写了一个示例类，它演示了两个文件的问题（一个有效，另一个无效）。

public class LoaderTest extends MovieClip {
    var output:TextField;
    var loader:Loader;
    var urlLoader:URLLoader;

    function LoaderTest() {
        output = new TextField();
        output.width = 1000;
        output.height = 1000;
        output.multiline = true;
        addChild(output);

        var t1:Timer = new Timer(0, 0);
        t1.addEventListener(TimerEvent.TIMER, function() {
            t1.stop(); loadMapDirect("map_in_big.png");
        });

        var t2:Timer = new Timer(1000, 0);
        t2.addEventListener(TimerEvent.TIMER, function() {
            t2.stop(); loadMapDirect("map_us_big.png");
        });

        var t3:Timer = new Timer(2000, 0);
        t3.addEventListener(TimerEvent.TIMER, function() {
            t3.stop(); loadMapBytes("map_in_big.png");
        });

        var t4:Timer = new Timer(3000, 0);
        t4.addEventListener(TimerEvent.TIMER, function() {
            t4.stop(); loadMapBytes("map_us_big.png");
        });

        t1.start();
        t2.start();
        t3.start();
        t4.start();

    }

    function loadMapBytes(url:String):void {
        try {
            urlLoader = new URLLoader();
            urlLoader.dataFormat = URLLoaderDataFormat.BINARY;
            urlLoader.addEventListener(ProgressEvent.PROGRESS, progressListener);
            urlLoader.addEventListener(Event.COMPLETE, completeListenerBytes);

            output.appendText("\nLoading '"+url+"' with URLLoader ");
            urlLoader.load(new URLRequest(url));
        } catch (error:Error) {
            output.appendText("Err: " + error.message + "\n");
        }

    }

    function completeListenerBytes(e:Event):void {
        output.appendText("COMPLETE Event fired for URLLoader!\n");

        try {
            loader = new Loader();
            loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressListener);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeListenerDirect);
            output.appendText("Loading bytes with Loader ");
            loader.loadBytes(e.target.data as ByteArray);
        } catch (error:Error) {
            output.appendText("Err: " + error.message + "\n");
        }
    }

    function loadMapDirect(url:String):void {
        try {
            loader = new Loader();
            loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressListener);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeListenerDirect);

            output.appendText("\nLoading '"+url+"' with Loader ");
            loader.load(new URLRequest(url));
        } catch (error:Error) {
            output.appendText("Err: " + error.message + "\n");
        }
    }

    function completeListenerDirect(e:Event):void {
        var bmd:BitmapData = Bitmap(e.target.loader.content).bitmapData;
        output.appendText("COMPLETE Event fired for Loader! => h: " +  bmd.height + ", w: " + bmd.width + "\n");
    }

    function progressListener (e:ProgressEvent):void{
        output.appendText(".");
        if (e.bytesLoaded == e.bytesTotal) {
            output.appendText(" progress complete, " + e.bytesTotal + " bytes loaded!\n");
        }
    }
}

所有图像都是使用 PHP GD 库生成的，我使用 SWFTools 的 as3compile 进行编译。

您可以在 http://www.wichte-sind 上查看脚本的运行情况-wichtig.de/as3loader/loaderTest.swf

两张图片map_in_big.png和map_us_big.png在同一个文件夹中（不允许发布更多超链接）。

有什么想法吗？

Answer 1

问题是您的应用程序可能是为 Flash Player 9 编译的。在版本 9 中，允许的最大图像尺寸为 2880 x 2800，map_us_big.png 为 3150 x 1570。当我为 Flash Player 10 编译该应用程序时，我成功运行了该应用程序。

以下是参考文献http://help.adobe .com/en_US/FlashPlatform/reference/actionscript/3/flash/display/BitmapData.html#BitmapData%28%29

在 AIR 1.5 和 Flash Player 10 中，BitmapData 的最大大小
对象的宽度或高度为 8,191 像素，并且对象的总数
像素不能超过 16,777,215 像素。 （因此，如果 BitmapData 对象是
宽 8,191 像素，高只能为 2,048 像素。）在 Flash Player 中
9 及更早版本和 AIR 1.1 及更早版本，限制为 2,880 像素
高度为 2,880 像素，宽度为 2,880 像素。如果指定宽度或高度
值大于 2880，则不会创建新实例。