复杂对象的常规闭包

Question

我如何为下面的复杂场景编写闭包，

def empList=[];
EmployeeData empData = null;
empData=new EmployeeDataImpl("anish","nath");
empList.add(empData );
empData=new EmployeeDataImpl("JOHN","SMITH");
empList.add(empData );

Employee employee= new Employee(empList);

如何编写闭包以便使用 emplyee 对象获得 empData 详细信息？有什么提示想法吗？

Answer 1

我不确定你的意思...

要迭代 EmployeeData，你可以使用 each：

empList.each { println it }

要查找特定条目，你可以使用 find：

// Assume EmployeeData has a firstName property, you don't show its structure
EmployeeData anish = empList.find { it.firstName == 'anish' }

或者你可以使用 findAll 找到所有具有给定姓氏的人：

def smiths = empList.findAll { it.surname == 'Smith' }

这取决于你想要“闭包”做什么...

编辑

对，在你解释了你的 DSL 之后你想要的，我想出了这个（这将解决给定的问题）：

@groovy.transform.Canonical
class EmployeeData {
  String firstName
  String lastName
}

class Employee {
  List<EmployeeData> empList = []

  Employee( List<EmployeeData> list ) {
    empList = list
  }
}

class EmployeeDSL {
  Employee root

  List propchain = []

  EmployeeDSL( Employee root ) {
    this.root = root
  }

  def propertyMissing( String name ) {
    // if name is 'add' and we have a chain of names
    if( name == 'add' && propchain ) {
      // add a new employee
      root.empList << new EmployeeData( firstName:propchain.take( 1 ).join( ' ' ), lastName:propchain.drop( 1 ).join( ' ' ) )
      // and reset the chain of names
      propchain = []
    }
    else {
      // add this name to the chain of names
      propchain << name
      this
    }
  }
}

Employee emp = new Employee( [] )

new EmployeeDSL( emp ).with {
  anish.nath.add
  tim.yates.add
}

emp.empList.each {
  println it
}

它使用 take() 和 drop()，所以你需要 groovy 1.8.1+

希望它有意义！然而，这有点奇怪的语法（使用关键字 add 将字符串添加为 Employee），与其这样，最好提出类似于 MarkupBuilder 的东西。代码>通过实施BuilderSupport