如何在 Vim 中一次性折叠整个文件到特定级别？

Question

我想在 Vim 中按一个按钮并折叠所有代码，以便只显示达到特定（和可变）缩进级别的代码。例如，当我只想查看方法名称而不是其缩进例程时，这非常有用。

“Vim: 仅折叠顶层折叠”问题有一个解决方案缩进级别，但每次更改级别时都需要设置环境。

当我的光标位于缩进级别（例如级别 2）时，我希望整个文件在所有方法中都折叠到该缩进级别。

这是 Vim 中内置的吗？有谁知道有一个好的插件可以做到这一点吗？

Answer 1

将折叠配置为通过缩进定义：

:setl foldmethod=indent

并尝试以下命令：

:let &l:foldlevel = indent('.') / &shiftwidth

要快速访问此命令，请为其创建映射，如下所示：

:nnoremap <silent> <leader>z :let&l:fdl=indent('.')/&sw<cr>

Answer 2

不需要插件，它内置在 Vim 中。

“foldlevel”（或更短的“fdl”）和“foldnestmax”（“fdn”）似乎就是我们正在寻找的。您只需在 .vimrc 文件中设置“foldmethod”（或更短的“fdm”）和“foldnestmax”（或“fdn”）：

set foldmethod=indent foldlevelstart=2 foldnestmax=2

或较短的版本：

set fdm=indent fdls=2 fdn=2

然后您可以使用直接命令更改折叠级别：zm或zr。

Answer 3

因为当foldmethod为expr时，foldnestmax不适用，所以当我遇到你的问题时，我寻找了其他东西。这是我想到的，毫无疑问可以改进：

function! <sid>CloseFoldOpens(opens_level)
    let lineno = 2
    let last = line("$")
    while lineno < last
        if foldclosed(lineno) != -1
            let lineno = foldclosedend(lineno) + 1
        elseif foldlevel(lineno) > foldlevel(lineno - 1)
        \ && foldlevel(lineno) == a:opens_level
            execute lineno."foldclose"
            let lineno = foldclosedend(lineno) + 1
        else
            let lineno = lineno + 1
        end
    endwhile
endfunction
nnoremap <silent> z1 :%foldclose<cr>
nnoremap <silent> z2 :call <sid>CloseFoldOpens(2)<cr>
nnoremap <silent> z3 :call <sid>CloseFoldOpens(3)<cr>
nnoremap <silent> z4 :call <sid>CloseFoldOpens(4)<cr>
nnoremap <silent> z5 :call <sid>CloseFoldOpens(5)<cr>

我更喜欢编号的地图，但对于您的基于当前行的缩进，大致如下：

nnoremap <silent> z. :call <sid>CloseFoldOpens(foldlevel('.'))<cr>zv