如何在设计时调用组件的属性编辑器

Question

我创建了一个从 TCustomPanel 派生的组件。在该面板上，我有一个从 TOwnedCollection 派生的类的已发布属性。一切运行良好，单击该属性的对象检查器中的省略号将打开默认集合编辑器，我可以在其中管理列表中的 TCollectionItems。

  TMyCustomPanel = class(TCustomPanel)
  private
  ...
  published
    property MyOwnedCollection: TMyOwnedCollection read GetMyOwnedCollection write SetMyOwnedCollection;
  end;

我还希望能够在设计时双击面板并默认打开集合编辑器。我首先创建一个从 TDefaultEditor 派生的类并注册它。

  TMyCustomPanelEditor = class(TDefaultEditor)
  protected
    procedure EditProperty(const PropertyEditor: IProperty; var Continue: Boolean); override;
  end;

  RegisterComponentEditor(TMyCustomPanel, TMyCustomPanelEditor);

这似乎是在正确的时间运行的，但我当时不知道如何启动集合的属性编辑器。

procedure TMyCustomPanelEditor.EditProperty(const PropertyEditor: IProperty; var Continue: Boolean);
begin
  inherited;

  // Comes in here on double-click of the panel
  // How to launch collection editor here for property MyOwnedCollection?

  Continue := false;
end;

任何解决方案或不同的方法将不胜感激。

Answer 1

据我所知，您没有使用正确的编辑器。 TDefaultEditor 的描述如下：

为双击提供默认行为的编辑器，该双击将迭代属性，查找最合适的方法属性进行编辑

这是一个编辑器，通过将您放入具有新创建事件的代码编辑器来响应表单上的双击处理程序。想象一下当您双击 TButton 并进入 OnClick 处理程序时会发生什么。

自从我编写设计时编辑器以来已经很长时间了（我希望今天我的记忆还可以），但我相信您的编辑器应该源自 TComponentEditor。为了显示集合编辑器，您可以从 ColnEdit 单元调用 ShowCollectionEditor。

您可以重写 TComponentEditor 的 Edit 方法，并从那里调用 ShowCollectionEditor。如果您想更高级，您也可以使用 GetVerbCount、GetVerb 和 ExecuteVerb 声明一些动词。如果您这样做，那么您将扩展上下文菜单，并且默认的 Edit 实现将执行动词 0。

Answer 2

根据 David 的正确答案，我想提供完整的代码，该代码显示在设计时双击 UI 控件的特定属性的 CollectionEditor。

type
  TMyCustomPanel = class(TCustomPanel)
  private
  ...
  published
    property MyOwnedCollection: TMyOwnedCollection read GetMyOwnedCollection write SetMyOwnedCollection;
  end;


  TMyCustomPanelEditor = class(TComponentEditor)
  public
    function GetVerbCount: Integer; override;
    function GetVerb(Index: Integer): string; override;
    procedure ExecuteVerb(Index: Integer); override;
  end;


procedure Register;
begin
  RegisterComponentEditor(TMyCustomPanel, TMyCustomPanelEditor);
end;

function TMyCustomPanelEditor.GetVerbCount: Integer;
begin
  Result := 1;
end;

function TMyCustomPanelEditor.GetVerb(Index: Integer): string;
begin
  Result := '';
  case Index of
    0: Result := 'Edit MyOwnedCollection';
  end;
end;

procedure TMyCustomPanelEditor.ExecuteVerb(Index: Integer);
begin
  inherited;
  case Index of
    0: begin
          // Procedure in the unit ColnEdit.pas
          ShowCollectionEditor(Designer, Component, TMyCustomPanel(Component).MyOwnedCollection, 'MyOwnedCollection');
       end;
  end;
end;