确定 Perl 代码引用的子例程名称

Question

如何确定 Perl 代码引用的子例程名称？我还想区分命名子例程和匿名子例程。

感谢 这个问题 我知道如何打印代码，但我仍然不知道如何获得这个名字。

例如，我想从以下内容获取“inigo_montoya”：

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Deparse = 1;

my $sub_ref = \&inigo_montoya;

print Dumper $sub_ref;



# === subroutines ===

sub inigo_montoya {
  print <<end_quote;
I will go up to the six-fingered man and say, "Hello. My name is Inigo
Montoya. You killed my father. Prepare to die."';
end_quote
}

Answer 1

为什么不问，编译器看到了什么？ （它会在匿名订阅者上返回__ANON__）。

#!/usr/bin/perl

use strict;
use warnings;

my $sub_ref = \&inigo_montoya;


use B qw(svref_2object);
my $cv = svref_2object ( $sub_ref );
my $gv = $cv->GV;
print "name: " . $gv->NAME . "\n";


sub inigo_montoya {
    print "...\n";
}

Answer 2

Sub::Identify 正是这样做的，隐藏了所有令人讨厌的 B::svref_2object( ) 来自您的东西，这样您就不必考虑它。

#!/usr/bin/env perl

use strict;
use warnings;
use feature 'say';

use Sub::Identify ':all';

my $sub_ref = \&inigo_montoya;

say "Sub Name: ",   sub_name($sub_ref);
say "Stash Name: ", stash_name($sub_ref);
say "Full Name: ",  sub_fullname($sub_ref);

# === subroutines ===

sub inigo_montoya {
    print <<'    end_quote';
I will go up to the six-fingered man and say, "Hello. My name is Inigo
Montoya. You killed my father. Prepare to die."';
    end_quote
}

哪个输出：

$ ./sub_identify.pl 
Sub Name: inigo_montoya
Stash Name: main
Full Name: main::inigo_montoya

Answer 3

扩展 Jan Hartung 的想法（并废弃我自己的想法），您可以获得完全限定的名称和一些跟踪信息，无论它是什么或来自哪里：

use B qw(svref_2object);

sub sub_name {
    return unless ref( my $r = shift );
    return unless my $cv = svref_2object( $r );
    return unless $cv->isa( 'B::CV' )
              and my $gv = $cv->GV
              ;
    my $name = '';
    if ( my $st = $gv->STASH ) { 
        $name = $st->NAME . '::';
    }
    my $n = $gv->NAME;
    if ( $n ) { 
        $name .= $n;
        if ( $n eq '__ANON__' ) { 
            $name .= ' defined at ' . $gv->FILE . ':' . $gv->LINE;
        }
    }
    return $name;
}

Answer 4

我不确定从外部调用函数的名称，但您可以通过 caller 函数：

sub Foo {print "foo!\n";return (caller(0))[3];}
$function_name=Foo();
print "Called $function_name\n";

它具有以下输出：

foo!
Called main::Foo

当然，您可以将函数名称作为子例程返回的项目之一返回。这样，您可以捕获它并可以选择显示它（或在其他逻辑中使用它等）。