在 Grails Audit Loggin 插件的 onChange 方法中，如何获取对所属可审核域对象的引用？

Question

我已经成功地让 grails 审核日志记录插件正常工作，看起来正是我所需要的，只是我无法弄清楚如何从 onChange 方法中获取对可审核域对象的引用。下面是插件示例 Person 类的代码，还有几行我想要实现的目标：

class Person {

   static auditable = true 
   Long id 
   Long version

   String firstName 
   String middleName 
   String lastName

   String email

   static hasMany = [emailRecords : EmailRecord]    
   static constraints = { 
      firstName(nullable:true,size:0..60) 
      middleName(nullable:true,size:0..60) 
      lastName(nullable:false,size:1..60) 
      email(email:true) 
   }

   def onSave = { 
      println "new person inserted" // may optionally refer to newState map 
   } 

   def onDelete = { 
      println "person was deleted" // may optionally refer to oldState map 
   } 

   def onChange = { 
     oldMap,newMap -> 
        println "Person was changed ..." 
        oldMap.each({ key, oldVal -> 
           if(oldVal != newMap[key]) { 
              println " * $key changed from $oldVal to " + newMap[key] 
              // how can achieve something like this?
              if(key == "email"){
                 def personInstance = this // this didn't work, I'm not sure how I can get such a reference to the owning domain object
                 personInstance.addToEmailRecords(
                    new EmailRecord(
                       email:newMap[key],
                       date: new Date()
                    ).save()
                 )
              }
           } 
        }) 
     }
   }

Answer 1

对于这个用例，您可能真的只想使用 标准 GORM 事件 使用 isDirty() 和 getPersistentValue() 至少进行更新。特别是，如审计日志插件文档中所述，它旨在在实体提交到数据存储后对其进行操作（因此，例如，保证分配对象 ID）。

尝试如下操作：

class Person {
    // blah, blah, blah
    def beforeInsert = {
        if (email) {
            addToEmailRecords(new EmailRecord(email: email, date: new Date()))
        }
    }

    def beforeUpdate = {
        if (isDirty("email")) {
            addToEmailRecords(new EmailRecord(email: email, date: new Date()))
        }
    }
}

这样，在提交更改后，您就不应该因修改对象而遇到任何麻烦。