如何在 Grails 中动态渲染 XML？

Question

我正在设置一个应用程序，该应用程序根据特定于每个呼叫实例的 XML 文件发起电话呼叫。出于测试目的，我使用 Groovy MarkupBuilder 和 StringWriter 方法将 XML 写入单个文件，然后在下次启动调用时覆盖该文件。

但是，这在生产中不起作用，因为我们将覆盖当前正在使用的 XML。因此，我想在控制器中动态创建 XML，方法是使用以下内容调用它：

callInstance.createXml()

使用“createXml”方法，其中包含如何专门为每个调用呈现 XML 的规则。

我发现很多人询问如何将对象转换为动态创建的 XML 文件，但这有点不同，因为我必须使用 MarkupBuilder。

为了快速参考，这里是我正在处理的小例子：

def f1 = new File('filename')
f1.delete()
def writer = new StringWriter()
        def xml = new MarkupBuilder(writer)
            xml.doubleQuotes = true
            xml.vxml(version:'2.1'){
                property(name:"termchar", value:"#")
                var(name:"hi", expr:"'Hello!'")
                xml.form(){
                    block(){
                        value(expr:"hi")
                        xml.goto(next:"#next") //etc, etc
                    }
                }
            }
        //break
        f1.createNewFile()
            f1 << writer.toString()

提前致谢！

Answer 1

您可以（在控制器中）做的一件事是 从渲染方法发送回 XML，如下所示：

def callxml = {
  def call = Call.get( params.id )
  render( contentType:"text/xml" ) {
    vxml( version:'2.1' ) {
      var( name:'hi', expr:call.message )
    }
  }
}

或者，您可以向 Call 类添加一个方法，这样它就知道如何将自身转换为 XML，如下所示字符串：

class Call {
  String message

  String toXml() {
    def writer = new StringWriter()
    new groovy.xml.MarkupBuilder( writer ).with { xml ->
      xml.doubleQuotes = true
      vxml(version:'2.1'){
        var(name:"hi", expr:"${this.message}")
      }
    }
    writer.toString()
  }
}

那么您应该能够调用 call.toXml()