Word 2007 单个单词的密码保护

Question

是否可以为word文档中的单个单词设置密码？

我想要的是根据我们的IT结构编写一个系统文档。我也想将密码放在文档中。现在我希望您必须输入“主”密码才能解锁文档内的密码。如果不输入密码，文档中的密码应该是不可见的或类似的。

这可能吗？

Answer 1

是的，这是可能的。为了完成这项工作，我们必须结合使用 Word 固有的文档保护、隐藏文本属性和一些 VBA 技巧。

首先，将文档中的所有密码格式化为隐藏文本。 （对于那些不熟悉的人来说，只有当“显示/隐藏”功能设置为 true 时，隐藏文本才可见。）

然后添加代码以确保隐藏文本不会显示，并在文档打开时保护文档不被编辑。打开：

Private Sub Document_Open()
AddProtection
End Sub

Sub AddProtection()
With ActiveDocument
    .ActiveWindow.View.ShowAll = False
    .ActiveWindow.View.ShowHiddenText = False
    .Application.Options.PrintHiddenText = False
    .Protect Type:=wdAllowOnlyReading, NoReset:=True, Password:="DesiredPassword"
End With
End Sub

因为Word用户通常可以在任何给定时间显示隐藏文本，所以我们也需要控制此功能。大多数菜单和功能区命令可以通过创建一个包含以拦截命令命名的子例程的模块来拦截。命名子 ShowAll 将允许我们控制此功能，并且仅在输入密码时显示隐藏文本：

Sub ShowAll()

If ActiveDocument.ProtectionType = wdAllowOnlyReading Then
    'Do nothing
Else 'restore the Ribbon's toggle function
    If ActiveDocument.ActiveWindow.View.ShowAll = True Then
        ActiveDocument.ActiveWindow.View.ShowAll = False
    Else
        ActiveDocument.ActiveWindow.View.ShowAll = True
    End If
End If

End Sub

最后，我们添加一些代码来提示用户输入密码，如果输入正确，则显示以前隐藏的文本：

Sub RemoveProtection()

Dim strPassword As String
strPassword = InputBox("Enter document password.")
ActiveDocument.Unprotect Password:=strPassword
If ActiveDocument.ProtectionType = wdNoProtection Then
    ActiveDocument.ActiveWindow.View.ShowHiddenText = True
End If

End Sub

输入所有 VBA 代码后，右键单击 IDE 中的模块，选择项目属性，然后在“保护”选项卡上分配单独的密码。这将阻止高级用户获取嵌入的密码或更改代码。

剩下要做的就是在 Word 中创建一个 QAT 按钮（仅对此文档可见）并为其分配 RemoveProtection 子项。每当打开文档时，密码都会被隐藏并防止编辑，但可以通过单击 QAT 按钮并输入正确的密码来显示。

编辑

当我第一次回答这个问题时，我没有考虑到Word有一个隐藏文本选项，可以与“全部显示”选项分开打开。此外，可以通过打印选项打印隐藏文本。我在上面的 AddProtection 中添加了代码来关闭这些设置。

进一步测试还表明，Word 2007 中的用户可以手动进入 Office Orb|选项|显示，通过更改显示所有格式标记 或 显示隐藏文本手动隐藏文本选项。为了避免这种情况，需要创建功能区自定义并将其与文档一起加载。

最后，值得注意的是，虽然让 Word 随心所欲地完成这样的任务很有趣，但保护程度不如单独加密密码，然后在泄露内容之前解密，甚至使用Word的文档密码功能对文档的全部内容进行加密。